equation solving - Solve[Tan[theta] == (b*Sin[t])/(a*Cos[t]), theta] breaks when "Reals" is added?

Mathematica solves this equation fine:

Solve[ Tan[theta] == (b*Sin[t])/(a*Cos[t]), theta] // InputForm          

{{theta -> ConditionalExpression[ArcTan[(b*Tan[t])/a] + Pi*C[1], 
  Element[C[1], Integers]]}}

The solution is real when $a$, $b$, and $t$ are real (and $t$ isn't a multiple of $\frac{\pi}{2}$). However, adding the Reals condition breaks things:

Solve[ Tan[theta] == (b*Sin[t])/(a*Cos[t]), theta, Reals] // InputForm   

Solve::nsmet: This system cannot be solved with the methods available to Solve.

Solve[Tan[theta] == (b*Tan[t])/a, theta, Reals]

Why?

Answer

The issue we encounter here is an apparent incompleteness of the recent updates in the system, we should remember that Solve has been updated in the recent versions of Mathematica and although documentation pages say "last modified in 8", one can distinguish various different issues between ver.8 and ver.9, it's just a state of art. In ver. 8 we get:

Solve[ Tan[θ] == b Sin[t]/(a Cos[t]), θ]

Solve::ifun: Inverse functions are being used by Solve, so 
some solutions may not be found; use Reduce for complete solution information. >>

{{θ -> ArcTan[(b Tan[t])/a]}}

while in ver. 9

Solve[ Tan[θ] == b Sin[t]/(a Cos[t]), θ]

{{θ -> ConditionalExpression[ArcTan[(b Tan[t])/a] + π C[1], C[1] ∈ Integers]}}

even though ConditionalExpression was added in ver.8.

There are more substantial issues, but the one above shows that we shouldn't expect behind the scenes a simple procedure yielding always predictable results.

By default underlying variables are assumed to be complex (if there are no algebraic inequalities) and then Solve returns a generic solution, thus it isn't as fine as one seems to believe. When we restrict the domain to Reals a bug may appear, see e.g. Issue with NSolve thus effectively domain specification may be regarded as an application of a different algorithm for searching the solution space. Specifying the domain one can exploit an option Method in Solve which by default is Automatic, see Options[ Solve, Method].

Whenever attempting to solve a transcendental equation involving a few symbolic variables (parameters) it is recommended using Reduce or at least Solve with the MaxExtraConditions option to get more information on the solution space, however the latter cannot always guarantee fully equivalent solution (one can find here a remarkable example), thus encountering more symbolic variables we would rather exploit Reduce.

Sometimes even apparently simple equations can be hard to solve symbolically, for more detailed discussion see What is the difference between Reduce and Solve?.
Here we use Solve in Reals:

θ /. Solve[ Tan[θ] == b Sin[t]/(a Cos[t]), θ, Reals, Method -> Reduce]

{ConditionalExpression[ 
     2 ArcTan[( Cot[t] (-a - b Tan[t] Sqrt[( Cot[t]^2 (a^2 + b^2 Tan[t]^2))/b^2]))/b]
   + 2 π C[1], (C[1] ∈ Integers && b > 0 && Tan[t] > 0) || 
               (C[1] ∈ Integers && b > 0 && Tan[t] < 0) || 
               (C[1] ∈ Integers && b < 0 && Tan[t] > 0) || 

               (C[1] ∈ Integers && b < 0 && Tan[t] < 0)], 
 ConditionalExpression[
     2 ArcTan[( Cot[t] (-a + b Tan[t] Sqrt[(Cot[t]^2 (a^2 + b^2 Tan[t]^2))/b^2]))/b] 
   + 2 π C[1], (C[1] ∈ Integers && b > 0 && Tan[t] > 0) || 
               (C[1] ∈ Integers && b > 0 && Tan[t] < 0) || 
               (C[1] ∈ Integers && b < 0 && Tan[t] > 0) || 
               (C[1] ∈ Integers && b < 0 && Tan[t] < 0)]}

slightly more detailed information would be found with:

Solve[ Tan[θ] == b Sin[t]/(a Cos[t]), θ, Reals, Method -> Reduce, 

       MaxExtraConditions -> All]

or

Reduce[ Tan[θ] == b Sin[t]/(a Cos[t]), θ, Reals]

Alternatively we should assume that all variables are real by suplementing the equation with a > 0 && b > 0 && t > 0 && θ > 0 without explicit domain specification:

θ /. Solve[ Tan[θ] == b Sin[t]/(a Cos[t]) && 
                a > 0 && b > 0 && t > 0 && θ > 0, θ]

{ConditionalExpression[ ArcTan[(b Tan[t])/a], 
   (a > 0 && b > 0 && 0 < t < π/2) ||
   (C[1] ∈ Integers && C[1] >= 1 && a > 0 && b > 0 && π C[1] < t < 1/2 (π + 2 π C[1]))]}, 

 ConditionalExpression[ ArcTan[(b Tan[t])/a] + π C[2], 
   ((C[1] | C[2]) ∈ Integers && 0 < t < π/2 && C[2] >= 1 && a > 0 && b > 0)   ||
   ((C[1] | C[2]) ∈ Integers && 1/2 (-π + 4 π C[1]) < t < 1/2 (π + 4 π C[1])
     && C[1] >= 1 && C[2] >= 1 && a > 0 && b > 0)                                ||
   ((C[1] | C[2]) ∈ Integers && 1/2 (π + 4 π C[1]) < t < 1/2 (3 π + 4 π C[1])
     && C[1] >= 0 && C[2] >= 1 && a > 0 && b > 0)]}}