front end - Close or Open, not OpenClose CellGroups for specific CellStyle

I am aware of the question

Close programmatically all cell groups in Mathematica

but I am trying to find out how to close only one kind of Cells in a notebook, e.g., only chapters or only sections or only subsection and so on. Any ideas? I know I can search for all, e.g., chapter cells with Cells[CellStyle->"Chapter"] and at some point I would have to use FrontEndTokenExecute["OpenCloseGroup"] but I can not figure out how to select the corresponding cell groups and use them with FrontEndTokenExecute["OpenCloseGroup"]. Any suggestions on how to complete the code

loccells = Cells[CellStyle->"Chapter"]
(*what I am missing*)
FrontEndTokenExecute["OpenCloseGroup"]

It would be important to leave all other cell types untouched, since the approach

nb = SelectedNotebook[];
SelectionMove[nb, All, Notebook]
FrontEndTokenExecute["SelectionCloseAllGroups"]

collapses also figures and other cell types I actually want to leave open. Thank you for your time!

FINAL EDIT: Kuba's last version solved my problem, see his answer and the comments. I still will leave my remarks untouched, just for documentation.

EDIT 1: sorry, may be I was not precise enough in my question. I am interested exactly on the opening/closing behavior you get by double clicking on the cell brackets of a cell group, which is triggered by FrontEndTokenExecute["OpenCloseGroup"]. I know I can open and close cells in a different way by changing the value of the attribute CellOpen->True/False, but a change in that attribute collapses the cell type and does not close it as I am interested in. If you want to see the difference, please test this palette I created just today based on Kuba's answer in any notebook(s)

MyPalette = Manipulate[

   (*** Notebook selection ***)
   , Style["Select notebook"]
   , {nb, Notebooks[], PopupMenu}
   , Delimiter
   (*** Input cells ***)
   , Style["Input cells"]
   , Column[
    {
     Button["Hide inputs", cells = Cells[nb, CellStyle -> "Input"]; 
      SetOptions[#, CellOpen -> False] & /@ cells, ImageSize -> 80]

     , Button["Show inputs", cells = Cells[nb, CellStyle -> "Input"]; 
      SetOptions[#, CellOpen -> True] & /@ cells, ImageSize -> 80]
     }
    ]
   , Delimiter
   (*** Close types with FrontEndTokenExecute ***)
   , Style["Close cell types"]
   , Column[
    {
     Button["Open/close sections",

      Do[
       SelectionMove[cell, All, Cell];
       FrontEndTokenExecute["OpenCloseGroup"]
       , {cell, Cells[nb, CellStyle -> "Section"]}
       ]
      ]
     , Button["Open/close subsections",
      Do[
       SelectionMove[cell, All, Cell];
       FrontEndTokenExecute["OpenCloseGroup"]

       , {cell, Cells[nb, CellStyle -> "Subsection"]}
       ]
      ]
     , Button["Open/close subsubsections",
      Do[
       SelectionMove[cell, All, Cell];
       FrontEndTokenExecute["OpenCloseGroup"]
       , {cell, Cells[nb, CellStyle -> "Subsubsection"]}
       ]
      ]

     }
    ]
   , Delimiter
   (*** Close types with CellOpen ***)
   , Style["Close cell types with CellOpen"]
   , Column[
    {
     Button["Hide sections", 
      cells = Cells[nb, CellStyle -> "Section"]; 
      SetOptions[#, CellOpen -> False] & /@ cells, ImageSize -> 80]

     , Button["Show sections", 
      cells = Cells[nb, CellStyle -> "Section"]; 
      SetOptions[#, CellOpen -> True] & /@ cells, ImageSize -> 80]
     }
    ]

   ];

CreatePalette[
 MyPalette

 , WindowTitle -> "Hide and show input code in notebooks"
 , Saveable -> False
 ]

If you want to test this palette directly on a formatted notebook with sections and subsection use this small example notebook (just evaluate it with ALT+v+o and you will get the palette with the different options for a selectable notebook)

Test 1.nb (Google drive link)

EDIT 2: Just a remark, not a complain. Kuba's new suggestion is more flexible but something is weird. You can use it first, but then if you close manually a section cell group manually using WholeCellGroupOpener->True by clicking on the, e.g., section title having this option available, then the code does NOT OPEN this manually activated cell any more. See this GIF

If you want to download this notebook, use this link

Test 2.nb (Google drive link)

This is not a complain, only a remark, since I am already very happy with both solution and you can still combine Kuba's first suggestion with his second. You can close all open groups with his second suggestion and open all groups with his first. Thanks Kuba!

Answer

Edit

I've updated the old solution to be more flexible. Now you can choose whether to close or to open a group.

openCloseAll[nb_, target_String, to : (Open | Closed)] := Do[
  SelectionMove[cell, All, CellGroup, AutoScroll -> False];
  With[{
    content = Block[
      {$Context = "FrontEnd`", $ContextPath = {"System`"}}, 
      NotebookRead[nb]

    ], 
    from = to /. {Closed -> Open, Open -> Closed}
   }, 
    If[ 
      MatchQ[content, Cell[CellGroupData[{Cell[_, target, ___], __}, from]]], 
      NotebookWrite[nb, Cell[CellGroupData[content[[1, 1]], to]], 
       AutoScroll -> False]
    ]
   ];
  , 

   {cell, Cells[CellStyle -> target]}
]

The Block is there to help with the problem that not documented options, like WholeCellGroupOpener after read/write procedure will get $CellContext` context and will stop working.

More about this issue in Programming scripts to create and modify Styleseets. Problems with Contexts

Nevertheless, now you can run e.g.:

openCloseAll[EvaluationNotebook[], "Subsection", Closed] (*for closing*)

or

openCloseAll[EvaluationNotebook[], "Subsection", Open] (*for opening*)

---

Old

That's easy but tricky, unless I've missed the point :)

Do[
 SelectionMove[cell, All, Cell];
 FrontEndTokenExecute["OpenCloseGroup"],
 {cell, Cells[CellStyle -> "Subsection"]}
 ]

Notice I'm moving to Cell not to CellGroup, that's because if you have an empty Subsection then a CellGroup will be the parent Section group.