plotting - How to plot a barycentric line

I want to plot a barycentric function on an equilateral triangle (ternary plot). For example

f1 = {Abs[Sin[x]], Mod[x, 2], Abs[Cos[x]]};

At the moment I evaluate a list of data points and join them with a line

Show[{b3["PlotAxis"],ListPlot[b3["Data"][Range[0,100,1/#],f1],Joined->True]}]&/@{1,10,100}

Where b3 is:

b3 = GetBarycentric[3];
b3["Axis"] = {{1/2, Sqrt[3]/2}, {1, 0}, {0, 0}};
b3["Convert"][{a_, b_, c_}, axis_: b3["Axis"]] := Module[{
    abc = {a, b, c}, sum = Total[{a, b, c}]},
   Piecewise[{{ (axis[[1]] a + axis[[2]] b)/sum, sum > 0}, {axis[[2]], sum <= 0}}]];
b3["Data"][values_, rlines_] := b3["Convert"][#] & /@ Transpose[rlines /. x -> values]
b3["PlotAxis"] := Graphics[{Thin, Line[{#1, #2, #3, #1}]}] & @@ b3["Axis"];

I can not use listplots 'Joined->True', because lines are intermittent.

How can I transform the function and plot it?

Answer

A ternary plot is a plot on the nonnegative unit simplex in $\mathbb{R}^3$, so apply an affine change of basis (and rescale f1 to be sure its values lie on the simplex):

ClearAll[f1];
f1[x_] := {Abs[Sin[x]], Mod[x, 2], Abs[Cos[x]]};

With[{xyToTernary = {{0, 1, 1/2}, {0, 0, Sqrt[3]/2}}}, 
 ParametricPlot[xyToTernary . (f1[x] / Total[f1[x]]), {x, 1, 3^5}, 

  AxesOrigin -> {0, 0}, PlotRange -> {0, 1}, 
  Prolog -> {White, EdgeForm[Black], Polygon[{{0, 0}, {1, 0}, {1/2, Sqrt[3]/2}}]}]
 ]

Due to the nature of your function, it would be a good idea to break it at integral values of x by including the option Exclusions -> Range[3^5]:

If you would like to visualize the 3D to 2D relationship inherent in these plots, you can ask Mathematica to do the projecting for you (but the 2D quality is degraded):

Show[
 Graphics3D[{White, EdgeForm[Black], Polygon[{{1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]},  

  ViewVector -> {1, 1, 1}, ViewPoint -> {-8, -8, -8}, 
  ViewVertical -> {0, 0, 1}, ViewCenter -> {1/3, 1/3, 1/3}, 
  ViewAngle -> \[Pi]/2,  Lighting -> {{"Ambient", White}}],
 ParametricPlot3D[f1[x] / Total[f1[x]], {x, 1, 3^5}, 
  Exclusions -> Range[3^5]], Axes -> {True, True, True}
 ]

(Image not shown.)