Skip to main content

plotting - Seeing coordinates in Graphics3D


I'm writing some structures built up from different strings that specify the coordinates of the lines. The code used to generate these is built up from a ton of user defined functions from my library, so posting them here doesn't work very well. However, I can provide an example here that'll suffice.


What my question is about is how to show the coordinates in the structures that I draw, when looking at them with Graphics3D. When plotting functions, there's always this right mouse button option that has get coordinates, which will tell me exactly where I am on the plot. For Graphics3D this doesn't appear to be there. The underlying grid however definitely exists, as the lines are drawn at exact coordinates.


So lets make an example. An example string based structure is


x = {{Line[{{-273.5, 180., 0.}, {-273.5, 250., 0.}, {-237.5, 250., 
      0.}, {-237.5, 180., 0.}, {-242.5, 180., 0.}, {-242.5, 245., 

      0.}, {-268.5, 245., 0.}, {-268.5, 180., 0.}, {-273.5, 180., 
      0.}}], Line[{{-242.5, 250., 0.}, {-242.5, 180., 0.}, {-206.5, 
      180., 0.}, {-206.5, 250., 0.}, {-211.5, 250., 0.}, {-211.5, 
      185., 0.}, {-237.5, 185., 0.}, {-237.5, 250., 0.}, {-242.5, 
      250., 0.}}], 
   Line[{{-211.5, 180., 0.}, {-211.5, 250., 0.}, {-175.5, 250., 
      0.}, {-175.5, 180., 0.}, {-180.5, 180., 0.}, {-180.5, 245., 
      0.}, {-206.5, 245., 0.}, {-206.5, 180., 0.}, {-211.5, 180., 
      0.}}], Line[{{-180.5, 250., 0.}, {-180.5, 180., 0.}, {-144.5, 
      180., 0.}, {-144.5, 250., 0.}, {-149.5, 250., 0.}, {-149.5, 

      185., 0.}, {-175.5, 185., 0.}, {-175.5, 250., 0.}, {-180.5, 
      250., 0.}}], 
   Line[{{-149.5, 180., 0.}, {-149.5, 250., 0.}, {-113.5, 250., 
      0.}, {-113.5, 180., 0.}, {-118.5, 180., 0.}, {-118.5, 245., 
      0.}, {-144.5, 245., 0.}, {-144.5, 180., 0.}, {-149.5, 180., 
      0.}}], 
   Line[{{-118.5, 250., 0.}, {-118.5, 180., 0.}, {-82.5, 180., 
      0.}, {-82.5, 250., 0.}, {-87.5, 250., 0.}, {-87.5, 185., 
      0.}, {-113.5, 185., 0.}, {-113.5, 250., 0.}, {-118.5, 250., 
      0.}}], Line[{{-87.5, 180., 0.}, {-87.5, 250., 0.}, {-51.5, 250.,

       0.}, {-51.5, 180., 0.}, {-56.5, 180., 0.}, {-56.5, 245., 
      0.}, {-82.5, 245., 0.}, {-82.5, 180., 0.}, {-87.5, 180., 0.}}]},
   222.}

I plot this using my plotting function


CoolView[x_] := 
 Graphics3D[x /. {Line -> Polygon}, ViewPoint -> {0, 0, 1}, 
  ImageSize -> Large]

And you can then see the structure with



CoolView[x[[1]]]

It looks like this enter image description here


While I can find the exact distance from my generated code if I try a little bit, preferably I'd like to find a way to for example read off the distance between the two fingers plotted above. That's my question, how I can do this. It should be precicely defined as the lines are drawn onto specific coordinates.



Answer



I am not sure how well the following is answering your question.


Here is the general idea:




  1. Write a function that finds distances from an arbitrary point to each of the lines defined by the polygons sides (line segments).





  2. Use some sort of dynamic manipulation to plot the most interesting point-segment distances.




I assume it is important to stay in 3D, but I was able to make a dynamic interface working only for 2D.


Code 3D


Here is a function for calculating distances from a point to polygon lines:


Clear[DistanceToAllPolygonLines]
DistanceToAllPolygonLines[rpoint_, polys : {_Polygon ..}] :=

  Block[{segments, distances},
   segments = Join @@ Map[Partition[#[[1]], 2, 1] &, polys];
   distances = 
    Map[Norm[Cross[rpoint - #[[1]], rpoint - #[[2]]]]/
       Norm[#[[2]] - #[[1]]] &, segments];
   Transpose[{segments, distances}]
   ];

See this article for the point-line distance formula.


Here is how we use the function above (in 3D):



rpoint = Flatten[RandomReal[#, 1] & /@ pointsRange]
res = DistanceToAllPolygonLines[rpoint, Cases[gr[[1]], _Polygon, \[Infinity]]];
Graphics3D[{gr[[1]], Map[{Blue, Tooltip[Line[#[[1]]], #[[2]]]} &, res],
  Arrowheads[Medium],
  Map[{Black, Arrow[{rpoint, Mean[#[[1]]]}], Text[#[[2]], Mean[Append[#[[1]], rpoint]]]} &, 
   Take[SortBy[res, Last], UpTo[6]]], 
  Red, PointSize[0.01], Point[rpoint]
  }, ViewPoint -> {0, 0, 1.8}, ImageSize -> 900]

enter image description here



Note the tooltip -- it is given to any line segment in blue.


Interactive interface 2D


Here is an interactive interface in 2D:


DynamicModule[{p},
 polys = gr[[1]] /. (x : {_?NumberQ, _?NumberQ, _?NumberQ}) :> Most[x];
 Column[{
   Slider2D[Dynamic[p], Transpose[Most@pointsRange]],
   Row[{"point:", Dynamic[p]}],
   Dynamic[
    (res = 

      DistanceToAllPolygonLines[Append[p, 0], 
       Cases[gr[[1]], _Polygon, \[Infinity]]];
     res = res /. (x : {_?NumberQ, _?NumberQ, _?NumberQ}) :> Most[x];
     Graphics[{GrayLevel[0.7], polys, 
       Map[{Blue, Tooltip[Line[#[[1]]], #[[2]]]} &, res],
       Arrowheads[Medium],
       Map[{Black, Arrow[{p, Mean[#[[1]]]}], 
          Text[#[[2]], Mean[Append[#[[1]], p]]]} &, 
        Take[SortBy[res, Last], UpTo[6]]], 
       Red, PointSize[0.01], Point[p]

       }, ImageSize -> 900, GridLines -> Automatic, Frame -> True])]
   }]]

enter image description here


Again notice the tooltip -- it is given to any segment in blue.


Comments

Post a Comment

Popular posts from this blog

functions - Get leading series expansion term?

Given a function f[x] , I would like to have a function leadingSeries that returns just the leading term in the series around x=0 . For example: leadingSeries[(1/x + 2)/(4 + 1/x^2 + x)] x and leadingSeries[(1/x + 2 + (1 - 1/x^3)/4)/(4 + x)] -(1/(16 x^3)) Is there such a function in Mathematica? Or maybe one can implement it efficiently? EDIT I finally went with the following implementation, based on Carl Woll 's answer: lds[ex_,x_]:=( (ex/.x->(x+O[x]^2))/.SeriesData[U_,Z_,L_List,Mi_,Ma_,De_]:>SeriesData[U,Z,{L[[1]]},Mi,Mi+1,De]//Quiet//Normal) The advantage is, that this one also properly works with functions whose leading term is a constant: lds[Exp[x],x] 1 Answer Update 1 Updated to eliminate SeriesData and to not return additional terms Perhaps you could use: leadingSeries[expr_, x_] := Normal[expr /. x->(x+O[x]^2) /. a_List :> Take[a, 1]] Then for your examples: leadingSeries[(1/x + 2)/(4 + 1/x^2 + x), x] leadingSeries[Exp[x], x] leadingSeries[(1/x + 2 + (1 - 1/x...
Post a Comment
Read more

How to thread a list

I have data in format data = {{a1, a2}, {b1, b2}, {c1, c2}, {d1, d2}} Tableform: I want to thread it to : tdata = {{{a1, b1}, {a2, b2}}, {{a1, c1}, {a2, c2}}, {{a1, d1}, {a2, d2}}} Tableform: And I would like to do better then pseudofunction[n_] := Transpose[{data2[[1]], data2[[n]]}]; SetAttributes[pseudofunction, Listable]; Range[2, 4] // pseudofunction Here is my benchmark data, where data3 is normal sample of real data. data3 = Drop[ExcelWorkBook[[Column1 ;; Column4]], None, 1]; data2 = {a #, b #, c #, d #} & /@ Range[1, 10^5]; data = RandomReal[{0, 1}, {10^6, 4}]; Here is my benchmark code kptnw[list_] := Transpose[{Table[First@#, {Length@# - 1}], Rest@#}, {3, 1, 2}] &@list kptnw2[list_] := Transpose[{ConstantArray[First@#, Length@# - 1], Rest@#}, {3, 1, 2}] &@list OleksandrR[list_] := Flatten[Outer[List, List@First[list], Rest[list], 1], {{2}, {1, 4}}] paradox2[list_] := Partition[Riffle[list[[1]], #], 2] & /@ Drop[list, 1] RM[list_] := FoldList[Transpose[{First@li...
Post a Comment
Read more

front end - keyboard shortcut to invoke Insert new matrix

I frequently need to type in some matrices, and the menu command Insert > Table/Matrix > New... allows matrices with lines drawn between columns and rows, which is very helpful. I would like to make a keyboard shortcut for it, but cannot find the relevant frontend token command (4209405) for it. Since the FullForm[] and InputForm[] of matrices with lines drawn between rows and columns is the same as those without lines, it's hard to do this via 3rd party system-wide text expanders (e.g. autohotkey or atext on mac). How does one assign a keyboard shortcut for the menu item Insert > Table/Matrix > New... , preferably using only mathematica? Thanks! Answer In the MenuSetup.tr (for linux located in the $InstallationDirectory/SystemFiles/FrontEnd/TextResources/X/ directory), I changed the line MenuItem["&New...", "CreateGridBoxDialog"] to read MenuItem["&New...", "CreateGridBoxDialog", MenuKey["m", Modifiers-...
Post a Comment
Read more