image processing - How to create a 1D vector by selecting a straight line in a given angle of 2D array

Suppose I have an image created by the code provided below. I want to select a line (1D vector) $ \left(y-y_{0}\right)=n\left(x-x_{0}\right) $ from the output image (2D matrix) by specifying $n$ and $\left(x_{0},y_{0}\right)$. Can anyone explain how to do this?

Code:

w1 = 600;
w2 = 600;
mask = Sum[
  RotateRight[
    Exp[I k] DiskMatrix[20, {w1, w2}], {k 100, k 200 }], {k, 2}] + 
    Exp[I 5] DiskMatrix[20, {w1, w2}] + 

    Sum[RotateLeft[Exp[I k] DiskMatrix[20, {w1, w2}], {k 200, k  }], {k, 1}]
<< Developer`
Image[RotateRight[
Re[Fourier[mask]], {w1/2, w2/2}]\[TensorProduct]ToPackedArray[{1.0, 0.3, 0.1}], Magnification -> 0.4]   

Answer

I'm sure you know that a line will almost never run through exact pixel positions. Therefore, you have two choices. First, you interpolate your image matrix and then you can sample as many points along the line as you like. In this case, I probably wouldn't recommend it because the values depend on the interpolation itself. Another, very easy way is to use an algorithm which is used draw an approximate line in a pixel grid.

Lucky for you we already had a post about his. Therefore, you can read in this answer how it is done and with the provided function, you will get the pixel coordinates along a line between points $p_0$ and $p_1$.

bresenham[p0_, p1_] := 
 Module[{dx, dy, sx, sy, err, newp}, {dx, dy} = Abs[p1 - p0];
  {sx, sy} = Sign[p1 - p0];
  err = dx - dy;
  newp[{x_, y_}] := 
   With[{e2 = 2 err}, {If[e2 > -dy, err -= dy; x + sx, x], 
     If[e2 < dx, err += dx; y + sy, y]}];
  NestWhileList[newp, p0, # =!= p1 &, 1]]

and then you take your image and use ImageData to get the pixel matrix. The extraction of the diagonal image is as simple as

img = Import["http://i.stack.imgur.com/FQthc.png"];
Extract[ImageData[img], bresenham[{1, 1}, ImageDimensions[img]]]

Final note: pay attention that the image matrix is reversed to what you see in the image. I guess you can do the transformation of a line in two-point form and yours by yourself.