Fitting piecewise functions

I have several large data sets which follow the following pattern: A position is measured, a force is applied until a new equilibrium is found.

I'd like to find a fit for the position, at least at the plateaus, and preferably of the inter lying section, which in this case approaches a line.
I tried fitting the data with Clip, and with Piecewise.

nlm = NonlinearModelFit[v40s1000h,Piecewise[{{a, x < A}, {b, x > B}}], {a, b, A, B, c, d}, x]

This creates a decent fit only if I specify the values for A and B, but then I have to estimate those values for each data set manually. It also doesn't really work to just add NMinimize, or add the piecewise part for the middle bit.
Is There anything else I can try?

Setting the A to 200 and B to 250 works decently.

http://s000.tinyupload.com/?file_id=35616536027018518052 << file

Answer

As usual, it's a matter of choosing a better starting values for the parameters.

I started writing this answer before the data file was uploaded, so here's some synthetic data:

data = Table[
   Interpolation[{{0, 1.1*^-6}, {200, 1.1*^-6}, {250, 9.5*^-7}, {500, 
       9.5*^-7}}, x, InterpolationOrder -> 1] + 
    2*^-8 RandomVariate[NormalDistribution[]], {x, 0, 500}];
ListPlot[data]

enter image description here

As @nikie suggested in the comments, you should define your model to return something in the intermediate values. I'll use a linear transition because that seems to match your data.

f[x_] := Piecewise[{{a, x < xa}, {a + (b - a) (x - xa)/(xb - xa), xa <= x < xb}, {b, xb <= x}}]

Now we do the fit:

fit = NonlinearModelFit[data, f[x], {a, b, xa, xb}, x];
fit // Normal // InputForm
(* Piecewise[{{1., x < 1.}, {1.016964195743597*^-6, 1. <= x}}, 0] *)

No good. Why? The documentation for NonlinearModelFit says "give starting values when parameters are far from the default value 1". Let's try that.

fit = NonlinearModelFit[data, f[x], {a, b, {xa, 100}, {xb, 200}}, x];
fit // Normal // InputForm
(* Piecewise[{{1.1004729741760495*^-6, x < 200.73035367387615}, 

  {1.1004729741760495*^-6 - 2.914483888454594*^-9*(-200.73035367387615 + x), 
   200.73035367387615 <= x < 253.00000699926912}, 
  {9.481339117040847*^-7, 253.00000699926912 <= x}}, 0] *)

That's better.

Show[ListPlot[data], Plot[fit[x], {x, 0, 500}, PlotStyle -> {Red, Thick}]]

enter image description here

Comments

plotting - Filling between two spheres in SphericalPlot3D

Manipulate[ SphericalPlot3D[{1, 2 - n}, {θ, 0, Pi}, {ϕ, 0, 1.5 Pi}, Mesh -> None, PlotPoints -> 15, PlotRange -> {-2.2, 2.2}], {n, 0, 1}] I cant' seem to be able to make a filling between two spheres. I've already tried the obvious Filling -> {1 -> {2}} but Mathematica doesn't seem to like that option. Is there any easy way around this or ... Answer There is no built-in filling in SphericalPlot3D . One option is to use ParametricPlot3D to draw the surfaces between the two shells: Manipulate[ Show[SphericalPlot3D[{1, 2 - n}, {θ, 0, Pi}, {ϕ, 0, 1.5 Pi}, PlotPoints -> 15, PlotRange -> {-2.2, 2.2}], ParametricPlot3D[{ r {Sin[t] Cos[1.5 Pi], Sin[t] Sin[1.5 Pi], Cos[t]}, r {Sin[t] Cos[0 Pi], Sin[t] Sin[0 Pi], Cos[t]}}, {r, 1, 2 - n}, {t, 0, Pi}, PlotStyle -> Yellow, Mesh -> {2, 15}]], {n, 0, 1}]

plotting - Plot 4D data with color as 4th dimension

I have a list of 4D data (x position, y position, amplitude, wavelength). I want to plot x, y, and amplitude on a 3D plot and have the color of the points correspond to the wavelength. I have seen many examples using functions to define color but my wavelength cannot be expressed by an analytic function. Is there a simple way to do this? Answer Here a another possible way to visualize 4D data: data = Flatten[Table[{x, y, x^2 + y^2, Sin[x - y]}, {x, -Pi, Pi,Pi/10}, {y,-Pi,Pi, Pi/10}], 1]; You can use the function Point along with VertexColors . Now the points are places using the first three elements and the color is determined by the fourth. In this case I used Hue, but you can use whatever you prefer. Graphics3D[ Point[data[[All, 1 ;; 3]], VertexColors -> Hue /@ data[[All, 4]]], Axes -> True, BoxRatios -> {1, 1, 1/GoldenRatio}]

plotting - Mathematica: 3D plot based on combined 2D graphs

I have several sigmoidal fits to 3 different datasets, with mean fit predictions plus the 95% confidence limits (not symmetrical around the mean) and the actual data. I would now like to show these different 2D plots projected in 3D as in but then using proper perspective. In the link here they give some solutions to combine the plots using isometric perspective, but I would like to use proper 3 point perspective. Any thoughts? Also any way to show the mean points per time point for each series plus or minus the standard error on the mean would be cool too, either using points+vertical bars, or using spheres plus tubes. Below are some test data and the fit function I am using. Note that I am working on a logit(proportion) scale and that the final vertical scale is Log10(percentage). (* some test data *) data = Table[Null, {i, 4}]; data[[1]] = {{1, -5.8}, {2, -5.4}, {3, -0.8}, {4, -0.2}, {5, 4.6}, {1, -6.4}, {2, -5.6}, {3, -0.7}, {4, 0.04}, {5, 1.0}, {1, -6.8}, {2, -4.7}, {3, -1.

Blog

Search This Blog