calculus and analysis - How to make traditional output for derivatives

Hello again after some pause. i have a problem how to present partial derivatives in traditional form, not as Mathematica gave it to me in its notation. So I want to present this

Subscript[S, 1]* (F1^(4,0))[x,y]+Subscript[S, 2]* (F1^(2,2))[x,y]

to have a look $S_1\frac{\partial ^4F_1(x,y)}{\partial x^4}+S_2\frac{\partial ^4F_1(x,y)}{\partial x^2\partial y^2}$

And if I have for example lot of different combination of derivatives terms I want to do this automatically . Is it possible?

Answer

The problem with using TraditionalForm@Defer is that it won't work as soon as the Defer is gone. So you always need an additional wrapper, different from the simple TraditionalForm wrapper, to get the desired output. It can sometimes be desirable to have the derivative formatted automatically for all TraditionalForm environments, e.g., in Graphics labels etc.

If, as you mention in the question, you have numerous combinations of derivatives, then the output quickly becomes cluttered if you keep writing out all the function arguments in a partial derivative. This is why I formatted the derivative without arguments in this answer.

An additional formatting requirement in traditional form would be to write ordinary derivatives with a straight derivative symbol to distinguish them from partial derivatives. This isn't automatically done by Mathematica in TraditionalForm output, so I added that case distinction in the linked answer.

The downside of the shortened notation in that answer was that you can't copy the formatted output and re-use it as input by pasting it back into a new line.

Here is a way to get the advantages of more readable short-hand notation in the displayed output while at the same time maintaining the ability to evaluate the output later:

Derivative /: 
 MakeBoxes[Derivative[α__][f1_][vars__?AtomQ], 
  TraditionalForm] := Module[{bb, dd, sp},
  MakeBoxes[dd, _] ^= 
   If[Length[{α}] == 1, "\[DifferentialD]", "∂"];
  MakeBoxes[sp, _] ^= "\[ThinSpace]";
  bb /: MakeBoxes[bb[x__], _] := RowBox[Map[ToBoxes[#] &, {x}]];
  TemplateBox[{ToBoxes[bb[dd^Plus[α], f1]], 

    ToBoxes[Apply[bb, 
      Riffle[Map[
        bb[dd, #] &, (Pick[{vars}, #]^Pick[{α}, #] &[
          Thread[{α} > 0]])], sp]]], 
    ToBoxes[Derivative[α][f1][vars]]}, "ShortFraction", 
   DisplayFunction :> (FractionBox[#1, #2] &), 
   InterpretationFunction :> (#3 &), Tooltip -> Automatic]]

TraditionalForm[D[f[x], x]]

$\frac{d f}{d x}$

TraditionalForm[D[f[x, y], x, x]]

$\frac{\partial^2 f}{\partial x^2}$

Note the absence of arguments $(x)$ and $(x,y)$, respectively, and the different symbols for partial and ordinary derivatives. Also, you can now copy any of the above outputs and paste them into an Input cell. The result is again recognized as the original derivative, without loss of information.

What I added to the original solution linked above is a TemplateBox that specifies both a DisplayFunction (using the original formatting in the previous answer), and an IntepretationFunction which simply contains the box form of the original derivative expression. The latter is used when you try to evaluate the output. Since the function arguments are kept in that expression, it can be evaluated without problems.

Edit:

Originally I allowed this simplified derivative display only to be applied when al the function variables are symbols, as mentioned in the comments. The reason is that the simplified notation is clumsy when the chain rule needs to be applied. In that case, it's better to identify the function slots as it's done in the built-in display of Derivative.

On the other hand, the restriction to symbolic variables may be too strong if you also want to get the shortened display with functions that have one or more variables set equal to a constant. So I now allow the display to work as long as the arguments are atomic, not necessarily symbols. This makes it possible to get the following (note x = 0):

TraditionalForm[D[f[0, y], y]]

$\frac{\partial f}{\partial y}$

The output can still be copied into an input cell to get back the original information: f^(0,1)[0,y].

Here I verify that for compositions of functions, I still get the more verbose display I prefer:

TraditionalForm[D[f[g[x], y], x]]

$f^{(1,0)}(g(x), y)\,\frac{d g}{d x}$