Skip to main content

How to create simple (tensor) product spaces?


Is it possible to work with simple tensor product spaces, like multiplying product states from quantum mechanics?


I basically have a simple two dimensional vector space, whose elements are represented by two dimensional vectors: $(1,0)$ and $(0,1)$ are the basis vectors. And I have 2x2 matrices acting on them.


What I want to do is to combine two or more of such vector space to a bigger one, so that I get states like this: $(1,0)\otimes (1,0)$, $(1,0)\otimes (0,1)$, $(0,1)\otimes (1,0)$ and $(0,1)\otimes (0,1)$ are the basis states of the combined vector space. Matrices should combine similarly like: $((1,2),(3,4))\otimes((1,2),(3,4))$


I tried different ways to achieve this: using the \[Circletimes] or the \[TensorProduct] symbols to combine them but in the end I do not get anything to work.



Answer



Here is the basic method, illustrated with the combination of two spin-1/2 particles. (Hopefully, the physics language is familiar or accessible; I don't really have an idea of where else this kind of construction is useful.)


sigmaZ = {{1, 0}, {0, -1}}
id = IdentityMatrix[2]
(* {{1, 0}, {0, -1}} *)

(* {{1, 0}, {0, 1}} *)

Let's suppose we want to compute the $z$ component of the total spin of two particles. The individual operators and the sum are


(sz[1] = KroneckerProduct[sigmaZ, id]) // MatrixForm
(sz[2] = KroneckerProduct[id, sigmaZ]) // MatrixForm
(sz[1, 2] = sz[1] + sz[2]) // MatrixForm

enter image description here


Now, we can make single-particle states (written in the eigenbasis of sigmaZ) using


state[1] = {s[1][1], s[1][-1]}

state[2] = {s[2][1], s[2][-1]}
(* {s[1][1], s[1][-1]} *)
(* {s[2][1], s[2][-1]} *)

(I am using this abstract indexing in order to keep track of the states and particles that each amplitude is associated with: s[2][-1], for instance, stands for the amplitude of particle 2 to be in the "down" state.)


Then, we can take the tensor product of these two states to form the two-particle state


state[1, 2] = KroneckerProduct[state[1], state[2]] // Flatten
(* {s[1][1] s[2][1], s[1][1] s[2][-1], s[1][-1] s[2][1], s[1][-1] s[2][-1]} *)

(Below, I will present an alternative to Flattening, but this is the way I prefer to do this). Note the ordering of the two-particle basis:




Particle 1, up; Particle 2 up


Particle 1, up; Particle 2 down


Particle 1, down; Particle 2 up


Particle 1, down; Particle 2 down



We can see by direct matrix multiplication that this is consistent with the ordering used in KroneckerProduct when constructing the two-particle operators:


sz[1].state[1, 2]
sz[2].state[1, 2]
(* {s[1][1] s[2][1], s[1][1] s[2][-1], -s[1][-1] s[2][1], -s[1][-1] s[2][-1]} *)

(* {s[1][1] s[2][1], -s[1][1] s[2][-1], s[1][-1] s[2][1], -s[1][-1] s[2][-1]} *)

We can see that when Particle 1 is in the down state, the amplitude gets multiplied by -1 when being acted on by sz[1], and so on. Note that we can also do


state[1, 2].sz[2]

with no problems.


Finally, we can construct our states in alternative ways. The ordering in Mathematica is consistent with many different ways of constructing the states. For instance,


Table[state[i, j], {i, 1, -1, -2}, {j, 1, -1, -2}] // Flatten
state @@@ Tuples[{1, -1}, 2]
(* {state[1, 1], state[1, -1], state[-1, 1], state[-1, -1]} *)

(* {state[1, 1], state[1, -1], state[-1, 1], state[-1, -1]} *)

Here, the first and second positions in the argument of state are, respectively, the spin of particle 1 and 2, and we can see that the ordering of the basis is respected.




Alternative to Flattening


If we feel like making column vectors and row vectors separately, then do the following:


columnState[1, 2] = KroneckerProduct[state[1], List /@ state[2]]
rowState[1, 2] = KroneckerProduct[List@state[1], state[2]]
columnState[1, 2] // MatrixForm
rowState[1, 2] // MatrixForm

(* {{s[1][1] s[2][1]}, {s[1][1] s[2][-1]}, {s[1][-1] s[2][1]}, {s[1][-1] s[2][-1]}} *)
(* {{s[1][1] s[2][1], s[1][1] s[2][-1], s[1][-1] s[2][1], s[1][-1] s[2][-1]}} *)

enter image description here


And of course,


rowState[1, 2] == Transpose@columnState[1, 2]
(* True *)

Now, Dotting the matrix with the vectors can only be done one way, and Mathematica will complain if we try to do things in the wrong order.


sz[1].columnState[1, 2] // MatrixForm

rowState[1, 2].sz[1] // MatrixForm

enter image description here


Comments

Popular posts from this blog

plotting - How to draw lines between specified dots on ListPlot?

I would like to create a plot where I have unconnected dots and some connected. So far, I have figured out how to draw the dots. My code is the following: ListPlot[{{1, 1}, {2, 2}, {3, 3}, {4, 4}, {1, 4}, {2, 5}, {3, 6}, {4, 7}, {1, 7}, {2, 8}, {3, 9}, {4, 10}, {1, 10}, {2, 11}, {3, 12}, {4,13}, {2.5, 7}}, Ticks -> {{1, 2, 3, 4}, None}, AxesStyle -> Thin, TicksStyle -> Directive[Black, Bold, 12], Mesh -> Full] I have thought using ListLinePlot command, but I don't know how to specify to the command to draw only selected lines between the dots. Do have any suggestions/hints on how to do that? Thank you. Answer One possibility would be to use Epilog with Line : ListPlot[ {{1, 1}, {2, 2}, {3, 3}, {4, 4}, {1, 4}, {2, 5}, {3, 6}, {4, 7}, {1, 7}, {2, 8}, {3, 9}, {4, 10}, {1, 10}, {2, 11}, {3, 12}, {4, 13}, {2.5, 7}}, Ticks -> {{1, 2, 3, 4}, None}, AxesStyle -> Thin, TicksStyle -> Directive[Black, Bold, 12], Mesh -> Full, Epilog -> { Line[ ...

list manipulation - Selecting multiple columns from a matrix?

Sample data: data = { {{2013, 1, 1}, 24.13, 167.67, 231.82}, {{2013, 1, 2}, 32.15, 170.92, 225.99}, {{2013, 1, 3}, 35.43, 172.68, 221.67}, {{2013, 1, 4}, 36.73, 173.05, 218.32}, {{2013, 1, 5}, 58.19, 165.96, 197.05}, {{2013, 1, 6}, 69.99, 163.50, 187.52}, {{2013, 1, 7}, 71.37, 154.21, 175.58}, {{2013, 1, 8}, 72.51, 149.66, 163.25}}; I want a DateListPlot with three graphs, so for a matrix formed by columns 1 and 2, one for columns 1 and 3, and 1 for columns 1 and 4. At the moment I'm using this code: data2 = Transpose[{data[[All, 1]], data[[All, 2]]}]; data3 = Transpose[{data[[All, 1]], data[[All, 3]]}]; data4 = Transpose[{data[[All, 1]], data[[All, 4]]}]; DateListPlot[{data2, data3, data4}, Joined -> True, Filling -> {3 -> {1}}] but I have a hunch that this can be done more efficiently. I don't like the Transpose s in particular. Any ideas? edit (for extra credit) What if I need to multiply the second column by 2, which in my solution is simp...

calculus and analysis - Integral of the Sinc product

Let us consider the following integral $$ B_n = \int_0^\infty \prod_{k=1,3,5,\dots}^n\frac{\sin (x/k)}{x/k}dx $$ By definition, Sinc[x] == Sin[x]/x , therefore B[n_?OddQ] := Integrate[Product[Sinc[x/k], {k, 1, n, 2}], {x, 0, Infinity}] B /@ Range[1, 13, 2] {Pi/2, Pi/2, Pi/2, Pi/2, Pi/2, Pi/2, Pi/2} OK, everything is fine. But... B[15] 467807924713440738696537864469 Pi/935615849440640907310521750000 What's going on? Answer As Eckhard wrote in comments B[n] is the n-th Borwein integral . (The letter B was not accidental :) ) This funny properties of Borwein integrals is related to the Fourier transform of Sinc function FourierTransform[Sinc[x], x, k] 1/2 Sqrt[Pi/2] (Sign[1 - k] + Sign[1 + k]) Plot[%, {k, -2, 2}, Filling -> 0] which is the box function. The result is $\pi/2$ while the sum $$ 1/3+1/5+\dots+1/n $$ B_n = \frac{\pi}{2} - \pi \bigg(\sum_{k=3,5,\ldots}^n\frac{1}{k} -1\biggr)^\frac{n-1}{2}\prod_{k=3,5,\dots}^n\frac{k}{k-1}. $$ For $n=15$ it is equal to $$ \frac{46780...