Skip to main content

numerics - A problem about function N


Toady,I have a problem about N,described as below:



For example


 N[1/3, 5]
(* ==> 0.33333*)

and N[1/3, 5] can make the result keep five significant figures.


data= RandomReal[{0, 2},8]
(* ==> {0.952811, 0.834171, 0.309447, 1.41046, 1.46811, 0.385663,1.50229,1.82034}*)

However,I want to make the data Keep four significant figures,so I use the function N[#, 4]&


N[#, 4]&/@data

(* ==> {0.952811, 0.834171, 0.309447, 1.41046, 1.46811, 0.385663,1.50229,1.82034}*)

Unfortunately,it failed.


My trail:


I copy the result,and paste in a input:


0.9528112485377731`, 0.8341711402854446`, 0.3094468949977962`, 
1.410457480346131`, 1.4681075372399688`, 0.38566305213741137`, 
1.502289805503937`, 1.820341132427437`

I wipe out the symbol `,and



data1= {0.9528112485377731, 0.8341711402854446, 0.3094468949977962, 
        1.410457480346131, 1.4681075372399688, 0.38566305213741137, 
        1.502289805503937, 1.820341132427437};
N[#, 4]&/@data1

==>(Wrong result,still keeping six significant figures )


{0.952811, 0.834171, 0.309447, 1.41046, 1.46811, 0.385663, 1.50229, 1.82034}

So my question is why and how to revise it?



Answer




Arbitrary and machine precision


It is important to understand that there are two different and in some respects separate numeric systems within Mathematica: machine-precision and arbitrary-precision. (I described this in brief here.)


Machine-precision numerics are much faster than arbitrary precision numerics, therefore it is normally undesirable to convert machine to arbitrary as you gain no precision and lose much performance. N respects this situation by not converting machine-precision numbers into arbitrary-precision numbers:


x = 1.23456789
Precision[x]


1.23457

MachinePrecision


y = N[x, 3]
Precision[y]


1.23457

MachinePrecision

Although this example is attempting to truncate a MachinePrecision number the corollary to this is that N also will not raise the precision of such as number. See: Confused by (apparent) inconsistent precision



The solution is not to use N for this operation. The correct tool will depend on your task.


Formatting


If this is to be a formatting operation use a formatting tool such as NumberForm:


NumberForm[data1, 4]


{0.9528, 0.8342, 0.3094, 1.41, 1.468, 0.3857, 1.502, 1.82}

There are multiple options and several related functions which should allow you to format your output quite precisely. See the documentation for more.


Converting to arbitrary precision



If you wish to convert machine-precision to arbitrary-precision use e.g. SetAccuracy or SetPrecision:


data2 = SetPrecision[data1, 4]


{0.9528, 0.8342, 0.3094, 1.410, 1.468, 0.3857, 1.502, 1.820}

Precision /@ data2


{4., 4., 4., 4., 4., 4., 4., 4.}


Note that although these numbers have less precision than machine precision they are still arbitrary precision numbers, and will incur the additional overhead of that system along with precision tracking etc.


Rounding a machine-precision number


Perhaps the most likely desire is the one I overlooked initially, as noted in the comments and further discussed in How do you round numbers so that it affects computation? you can indeed Round a machine-precision number to approximate fewer digits, but be aware that you are truncating (zero-filling) binary digits therefore things may not work exactly as you expect. For example:


data3 = Round[data1, 0.001]


{0.953, 0.834, 0.309, 1.41, 1.468, 0.386, 1.502, 1.82}

data3 // InputForm



{0.9530000000000001, 0.834, 0.309, 1.41, 1.468, 0.386, 1.502, 1.82}

Note the first element.


Comments

Post a Comment

Popular posts from this blog

functions - Get leading series expansion term?

Given a function f[x] , I would like to have a function leadingSeries that returns just the leading term in the series around x=0 . For example: leadingSeries[(1/x + 2)/(4 + 1/x^2 + x)] x and leadingSeries[(1/x + 2 + (1 - 1/x^3)/4)/(4 + x)] -(1/(16 x^3)) Is there such a function in Mathematica? Or maybe one can implement it efficiently? EDIT I finally went with the following implementation, based on Carl Woll 's answer: lds[ex_,x_]:=( (ex/.x->(x+O[x]^2))/.SeriesData[U_,Z_,L_List,Mi_,Ma_,De_]:>SeriesData[U,Z,{L[[1]]},Mi,Mi+1,De]//Quiet//Normal) The advantage is, that this one also properly works with functions whose leading term is a constant: lds[Exp[x],x] 1 Answer Update 1 Updated to eliminate SeriesData and to not return additional terms Perhaps you could use: leadingSeries[expr_, x_] := Normal[expr /. x->(x+O[x]^2) /. a_List :> Take[a, 1]] Then for your examples: leadingSeries[(1/x + 2)/(4 + 1/x^2 + x), x] leadingSeries[Exp[x], x] leadingSeries[(1/x + 2 + (1 - 1/x...
Post a Comment
Read more

mathematical optimization - Minimizing using indices, error: Part::pkspec1: The expression cannot be used as a part specification

I want to use Minimize where the variables to minimize are indices pointing into an array. Here a MWE that hopefully shows what my problem is. vars = u@# & /@ Range[3]; cons = Flatten@ { Table[(u[j] != #) & /@ vars[[j + 1 ;; -1]], {j, 1, 3 - 1}], 1 vec1 = {1, 2, 3}; vec2 = {1, 2, 3}; Minimize[{Total@((vec1[[#]] - vec2[[u[#]]])^2 & /@ Range[1, 3]), cons}, vars, Integers] The error I get: Part::pkspec1: The expression u[1] cannot be used as a part specification. >> Answer Ok, it seems that one can get around Mathematica trying to evaluate vec2[[u[1]]] too early by using the function Indexed[vec2,u[1]] . The working MWE would then look like the following: vars = u@# & /@ Range[3]; cons = Flatten@{ Table[(u[j] != #) & /@ vars[[j + 1 ;; -1]], {j, 1, 3 - 1}], 1 vec1 = {1, 2, 3}; vec2 = {1, 2, 3}; NMinimize[ {Total@((vec1[[#]] - Indexed[vec2, u[#]])^2 & /@ R...
Post a Comment
Read more

plotting - Plot 4D data with color as 4th dimension

I have a list of 4D data (x position, y position, amplitude, wavelength). I want to plot x, y, and amplitude on a 3D plot and have the color of the points correspond to the wavelength. I have seen many examples using functions to define color but my wavelength cannot be expressed by an analytic function. Is there a simple way to do this? Answer Here a another possible way to visualize 4D data: data = Flatten[Table[{x, y, x^2 + y^2, Sin[x - y]}, {x, -Pi, Pi,Pi/10}, {y,-Pi,Pi, Pi/10}], 1]; You can use the function Point along with VertexColors . Now the points are places using the first three elements and the color is determined by the fourth. In this case I used Hue, but you can use whatever you prefer. Graphics3D[ Point[data[[All, 1 ;; 3]], VertexColors -> Hue /@ data[[All, 4]]], Axes -> True, BoxRatios -> {1, 1, 1/GoldenRatio}]
Post a Comment
Read more