calculus and analysis - Definite integral of a real function outputs complex number

I was just wondering how such an integral:

Integrate[(1.2 - 0.05 x)^2 x^4 ((1 - 0.85 (1.2 - 0.05 x))^0.5 (2 + 
  0.85 (1.2 - 0.05 x)) - (1 + 1.7 (1.2 - 0.05 x)) ArcCos[
 0.85 (1.2 - 0.05 x)]),{x,0,8}]

would output a complex number. How is so? Is this some sort of error? Should I add some sort of assumption? Or suggest an integration method (numerical)? I've tried some yet a still get a complex result.

Answer

There is in fact a problem with evaluating the integral

Let's save the integrand:

int = (1.2 - 0.05 x)^2 x^4 ((1 - 0.85 (1.2 - 0.05 x))^(1/2) *
       (2 + 0.85 (1.2 - 0.05 x)) - (1 + 1.7 (1.2 - 0.05 x)) ArcCos[0.85 (1.2 - 0.05 x)]);

It seems there is more to the OP's integral than just why does it return complex values:

Integrate[int, {x, 0, 8}]
(*  -1833.02 - 268.546 I  *)

Integrate[int, {x, 8/17, 8}]
Integrate[int, {x, 0, 8/17}]
% + %%
(*
  -2101.56 + 2.15407*10^-25 I

  0. + 849215. I
  -2101.56 + 849215. I
*)

NIntegrate[int, {x, 0, 8}]
(*  -2101.56 - 0.0000559972 I  *)

These are inconsistent results.

Rationalizing doesn't help:

ratint = Simplify@Rationalize[int]

Integrate[ratint, {x, 0, 8}]
(* 
  -(1/3200000)(-24 + x)^2 x^4 ((-1208 + 17 x) Sqrt[-8 + 17 x] - 
      40 (-608 + 17 x) ArcCos[-(17/400) (-24 + x)])
*)

Throw::sysexc: Uncaught SystemException returned to top level. Can be caught with Catch[[Ellipsis], _SystemException].

SystemException["MemoryAllocationFailure"]

[Added 6/20/2017.] However, if we split the integral at the singularity at x == 8/17 where the square root (1 - 0.85 (1.2 - 0.05 x))^(1/2) goes from imaginary to real, rationalizing the integrand does work:

Integrate[ratint, {x, 0, 8/17}] + Integrate[ratint, {x, 8/17, 8}]
N[%]
(*
  
  -2101.56 - 0.000420871 I
*)

How to fix it

[Added 6/20/2017.] An easier way than the original below is to pass NIntegrate[] the singular point. Then it integrates quite easily and stably (as the precision is increased):

NIntegrate[int, {x, 0, 8/17, 8}]
NIntegrate[ratint, {x, 0, 8/17, 8}, WorkingPrecision -> 24] (* need high prec. integrand *)
NIntegrate[ratint, {x, 0, 8/17, 8}, WorkingPrecision -> 50]
(*
  -2101.56 - 0.000421068 I
  -2101.56245616445471106361 - 0.00042087103162815865 I
  -2101.5624561644547110636118139788605647565220617959 - 
     0.0004208710316281586476679535473306338243068408 I
*)

Note that in the machine precision answer, the PrecisionGoal will be around 8 digits relative to the magnitude of the answer, which is about 2000. Therefore one should expect the imaginary part to be accurate to 4 or so decimal places. If we compared these answers with the first NIntegrate[] result -2101.56 - 0.0000559972 I, the relative error is 2*^-7, just slightly worse than expected. Singularities tend to make the error estimator perform worse.

[Original answer -- there may be some value in its demonstration of determining an appropriate WorkingPrecision setting, even though it is not the best approach to this problem.] The common advice about avoiding approximate reals in exact solvers like Integrate does not appear to be helpful. But we can increase the precision. Note how much precision is lost, if we start with 50 digits (more than half). This is an ill-conditioned problem.

Integrate[SetPrecision[int, 50], {x, 0, 8}]
(*  -2101.56245616445443429289 - 0.00042087103162815114 I  *)

Precision[%]
(*  23.4808  *)

The imaginary part doesn't quite agree with the numerical result above. Perhaps we should verify the numerical result by increasing its WorkingPrecision a bit.

NIntegrate[SetPrecision[int, 24], {x, 0, 8},
 WorkingPrecision -> 24, MaxRecursion -> 20]
(*  -2101.56245616445443049217 - 0.00042087103155248696 I  *)

That seems better. I think we can have some confidence in the first several digits of the answer.

Blog

Search This Blog