Skip to main content

graphics - What is wrong with triangle PlotMarkers in v.10.0.0?



Bug introduced in 10.0.0 and fixed in 10.0.1



In Mathematica 10.0.0 we have built-in graphical triangle PlotMarkers. Let us look closer on them:


ListLinePlot[{{Missing[]}, {{0, 0}}}, PlotTheme -> "Monochrome", 
 ImageSize -> 20, Ticks -> False, AxesOrigin -> {0, 0}, 
 BaseStyle -> {Magnification -> 10, Thickness -> Tiny}]

ListLinePlot[{{Missing[]}, {{0, 0}}}, 
 PlotTheme -> {"OpenMarkersThick", "LargeLabels"}, ImageSize -> 20, 
 Ticks -> False, AxesOrigin -> {0, 0}, 

 BaseStyle -> {Magnification -> 10, Thickness -> Tiny}]


plot1


plot2



It is clear that there is something wrong with the triangles. Is this functionality implemented correctly?



Answer



The triangle plot markers


It is natural to expect that the triangle marker is placed in such a way that its center of mass (center of circumcircle) coincides with the point it marks. That's how it is implemented in all major scientific plotting software, for example Origin:



plot markers in Origin 7.5


Some time ago I published my own implementation of triangle-based plot markers. Let us check how the new markers are implemented:


ListLinePlot[{{Missing[]}, {{0, 0}}}, PlotTheme -> "Monochrome", 
 ImageSize -> 10, Ticks -> False, AxesOrigin -> {0, 0}, 
 BaseStyle -> {Magnification -> 10, Thickness -> Tiny}]
%[[1, 2, 2, 2, -1]] // InputForm


screenshot


GeometricTransformation[Inset[Graphics[{<...>

      Line[{Offset[{0., 2.7625}], 
        Offset[{-2.7625, -2.022290355909023}], 
        Offset[{2.7625, -2.022290355909023}], 
        Offset[{0., 2.7625}]}]}], {0., 0.}],
     {{{0., 0.}}, {{0., 0.}}}]

Apart of the fact that the curve is not closed, the triangle is positioned in a strange way: the "center" is placed on the


2.022290355909023/(2.7625 + 2.022290355909023)



0.4226497308103742



part of the height of the triangle instead of expected 1/3 (the center of circumcircle). So current implementation is clearly wrong and leads to producing incorrect plots. Here is an example of correct implementation:


Graphics[{AbsoluteThickness[1], JoinedCurve[
   Line[{Offset[{0, 2}], Offset[{Sqrt[3], -1}], 
     Offset[{-Sqrt[3], -1}]}], CurveClosed -> True]},
 ImageSize -> 10, Axes -> True, Ticks -> False, AxesOrigin -> {0, 0}, 
 BaseStyle -> {Magnification -> 10, Thickness -> Tiny}]



screenshot



The following is correct implementation of both empty and filled triangle plot markers of strictly identical sizes with consistent explicit control over their sizes and thickness:


emptyUpTriangle = 
  Graphics[{AbsoluteThickness[absoluteThickness], 
    JoinedCurve[Line[{Offset[size {0, 2}], Offset[size {Sqrt[3], -1}], 
       Offset[size {-Sqrt[3], -1}]}], CurveClosed -> True]}, 
   AlignmentPoint -> {0, 0}];
filledUpTriangle = 
  Graphics[{Triangle[{Offset[size {0, 2} + absoluteThickness {0, 1}], 

      Offset[size {Sqrt[3], -1} + absoluteThickness {Sqrt[3/4], -1/2}], 
      Offset[size {-Sqrt[3], -1} + absoluteThickness {-Sqrt[3/4], -1/2}]}]}, 
   AlignmentPoint -> {0, 0}];
{emptyLeftTriangle, filledLeftTriangle, emptyDownTriangle, 
   filledDownTriangle, emptyRightTriangle, filledRightTriangle} = 
  Flatten[{emptyUpTriangle, filledUpTriangle} /. {x_?NumericQ, y_?NumericQ} :> 
       RotationTransform[#][{x, y}] & /@ {Pi/2, Pi/3, -Pi/2}];

SeedRandom[12]
ListLinePlot[Accumulate /@ RandomReal[3, {8, 10}] Range[8], 

 PlotMarkers -> {emptyUpTriangle, filledUpTriangle, emptyLeftTriangle,
    filledLeftTriangle, emptyDownTriangle, filledDownTriangle, 
   emptyRightTriangle, filledRightTriangle}, AspectRatio -> 1]

plot


And here is an extended version which includes open triangles with white filling:


size = 4; absoluteThickness = 2;

triangle[Up, Empty] = 
  Graphics[{AbsoluteThickness[absoluteThickness], 

    JoinedCurve[Line[{Offset[size {0, 2}], Offset[size {Sqrt[3], -1}], 
       Offset[size {-Sqrt[3], -1}]}], CurveClosed -> True]}, 
   AlignmentPoint -> {0, 0}];
triangle[Up, Filled] = 
  Graphics[{Triangle[{Offset[size {0, 2} + absoluteThickness {0, 1}], 
      Offset[size {Sqrt[3], -1} + absoluteThickness {Sqrt[3/4], -1/2}], 
      Offset[size {-Sqrt[3], -1} + absoluteThickness {-Sqrt[3/4], -1/2}]}]}, 
   AlignmentPoint -> {0, 0}];
triangle[Up, Open] = 
  Graphics[{{White, Triangle[{Offset[size {0, 2}], Offset[size {Sqrt[3], -1}], 

       Offset[size {-Sqrt[3], -1}]}]}, {AbsoluteThickness[absoluteThickness], 
     JoinedCurve[Line[{Offset[size {0, 2}], Offset[size {Sqrt[3], -1}], 
        Offset[size {-Sqrt[3], -1}]}], CurveClosed -> True]}}, 
   AlignmentPoint -> {0, 0}];
triangle[dir_: {Up, Right, Down, Left}, fill_: {Empty, Filled, Open}] := 
 triangle[Up, fill] /. {x_?NumericQ, y_?NumericQ} :> 
   RotationTransform[dir /. {Right -> -Pi/2, Down -> Pi/3, Left -> Pi/2}][{x, y}]

pl = ListPlot[Flatten[Table[{{n, y}}, {y, Range[2]}, {n, 6}], 1], 
  PlotMarkers -> 

   Flatten@Table[triangle[dir, fill], 
            {dir, {Up, Right, Down, Left}}, {fill, {Empty, Filled, Open}}], 
            GridLines -> {Range[6], Range[2]}, 
  PlotRange -> {{0, 7}, {0, 3}}, Axes -> False, Frame -> True]

plot2



Other plot markers


Not only triangle plot markers have problems:


ListLinePlot[{{#, 0}} & /@ Range[5], PlotTheme -> "Monochrome", 

 ImageSize -> 70, Ticks -> False, Axes -> False, Frame -> True, 
 BaseStyle -> {Magnification -> 15, Thickness -> Tiny}, 
 PlotRange -> {{0.5, 5.5}, All}, AspectRatio -> 1/10, 
 FrameTicks -> None, BaselinePosition -> Center, 
 GridLines -> {Range[5], {0}}, 
 GridLinesStyle -> Directive[{Dashing[None], Gray}], 
 Method -> {"GridLinesInFront" -> True}]
Cases[%, g_Graphics :> 
  Show[g, ImageSize -> 8, BaseStyle -> {Magnification -> 16}, 
   BaselinePosition -> Center], Infinity]

Cases[%[[4]], _Line, Infinity]


screenshot


{Line[{Offset[{-2.5, -2.5}],   Offset[{2.125, -2.125}], 
       Offset[{2.125, 2.125}], Offset[{-2.125, 2.125}], 
       Offset[{-2.125, -2.125}]}]}

As one can see, the square starts from the point {-2.5, -2.5} and ends in {-2.125, -2.125}!


Comments

Post a Comment

Popular posts from this blog

mathematical optimization - Minimizing using indices, error: Part::pkspec1: The expression cannot be used as a part specification

I want to use Minimize where the variables to minimize are indices pointing into an array. Here a MWE that hopefully shows what my problem is. vars = u@# & /@ Range[3]; cons = Flatten@ { Table[(u[j] != #) & /@ vars[[j + 1 ;; -1]], {j, 1, 3 - 1}], 1 vec1 = {1, 2, 3}; vec2 = {1, 2, 3}; Minimize[{Total@((vec1[[#]] - vec2[[u[#]]])^2 & /@ Range[1, 3]), cons}, vars, Integers] The error I get: Part::pkspec1: The expression u[1] cannot be used as a part specification. >> Answer Ok, it seems that one can get around Mathematica trying to evaluate vec2[[u[1]]] too early by using the function Indexed[vec2,u[1]] . The working MWE would then look like the following: vars = u@# & /@ Range[3]; cons = Flatten@{ Table[(u[j] != #) & /@ vars[[j + 1 ;; -1]], {j, 1, 3 - 1}], 1 vec1 = {1, 2, 3}; vec2 = {1, 2, 3}; NMinimize[ {Total@((vec1[[#]] - Indexed[vec2, u[#]])^2 & /@ R...
Post a Comment
Read more

functions - Get leading series expansion term?

Given a function f[x] , I would like to have a function leadingSeries that returns just the leading term in the series around x=0 . For example: leadingSeries[(1/x + 2)/(4 + 1/x^2 + x)] x and leadingSeries[(1/x + 2 + (1 - 1/x^3)/4)/(4 + x)] -(1/(16 x^3)) Is there such a function in Mathematica? Or maybe one can implement it efficiently? EDIT I finally went with the following implementation, based on Carl Woll 's answer: lds[ex_,x_]:=( (ex/.x->(x+O[x]^2))/.SeriesData[U_,Z_,L_List,Mi_,Ma_,De_]:>SeriesData[U,Z,{L[[1]]},Mi,Mi+1,De]//Quiet//Normal) The advantage is, that this one also properly works with functions whose leading term is a constant: lds[Exp[x],x] 1 Answer Update 1 Updated to eliminate SeriesData and to not return additional terms Perhaps you could use: leadingSeries[expr_, x_] := Normal[expr /. x->(x+O[x]^2) /. a_List :> Take[a, 1]] Then for your examples: leadingSeries[(1/x + 2)/(4 + 1/x^2 + x), x] leadingSeries[Exp[x], x] leadingSeries[(1/x + 2 + (1 - 1/x...
Post a Comment
Read more

What is and isn't a valid variable specification for Manipulate?

I have an expression whose terms have arguments (representing subscripts), like this: myExpr = A[0] + V[1,T] I would like to put it inside a Manipulate to see its value as I move around the parameters. (The goal is eventually to plot it wrt one of the variables inside.) However, Mathematica complains when I set V[1,T] as a manipulated variable: Manipulate[Evaluate[myExpr], {A[0], 0, 1}, {V[1, T], 0, 1}] (*Manipulate::vsform: Manipulate argument {V[1,T],0,1} does not have the correct form for a variable specification. >> *) As a workaround, if I get rid of the symbol T inside the argument, it works fine: Manipulate[ Evaluate[myExpr /. T -> 15], {A[0], 0, 1}, {V[1, 15], 0, 1}] Why this behavior? Can anyone point me to the documentation that says what counts as a valid variable? And is there a way to get Manpiulate to accept an expression with a symbolic argument as a variable? Investigations I've done so far: I tried using variableQ from this answer , but it says V[1...
Post a Comment
Read more