plotting - Generating high quality charts in Mathematica for use in LaTeX and Word

I frequently have a probelem using my charts in reports because the text (axes labels and tick marks) look low resolution (fuzzy). When I export my charts, i export them as PNG files. Unless I'm mistaken, this is the correct file format for vector graphics.

In Mathematica, the charts look great at any size, but when I export and drag them into Word, they don't look nearly as nice any more.

Does any one have any tricks they use to use the Mathematica charts in applications like Word?

Answer

You don't say whether you want high quality for printing or for viewing on screen. Unfortunately, in Word, you often have to pick one or the other. Which is not always an easy decision, for example if you're emailing a report to someone and you don't know if they will read it on screen or print it out.

In my experience the best approach for good quality printing from Word is to use a bitmap (raster format), but make sure you export at high resolution. The main advantage is that what you see in Mathematica is what you get on paper. You can use opacity, dashing, fancy typesetting and it will all work. Disadvantages are large file size and the fact that Word does a truly appalling job of resampling the image for display - you will see a very fuzzy image on screen.

For a good compromise between print and screen quality, I use a metafile (vector format). The advantage is that the quality is the same at any size, and generally acceptable for both on screen viewing and printing. The disadvantage is that there are usually slight differences between what you see in Mathematica and what you get in Word. For example text sizes, tick marks and dashing spacing might all change. Also opacity tends not to print very well. You also need to be careful not to create a metafile containing text in Mathematica fonts which the recipient of the report may not have. This can be avoided with a well known trick to convert text to curves by converting to PDF and back.

I use these two buttons to copy graphics for Word, either as bitmap or metafile:

Row@{Button["Metafile",
   With[{sd = Options[ButtonNotebook[], StyleDefinitions]},
    SetOptions[ButtonNotebook[], 
     Options[InputNotebook[], StyleDefinitions]];
    CopyToClipboard[First@ImportString[
        ExportString[ToExpression@NotebookRead@InputNotebook[], "PDF"],
        "TextOutlines" -> True]~Magnify~2];
    SetOptions[ButtonNotebook[], sd]]],
  Button["Bitmap",
   With[{sd = Options[ButtonNotebook[], StyleDefinitions]},

    SetOptions[ButtonNotebook[], 
     Options[InputNotebook[], StyleDefinitions]];
    CopyToClipboard[ImportString[
      ExportString[ToExpression@NotebookRead@InputNotebook[], "PNG", 
       ImageResolution -> 300]]];
    SetOptions[ButtonNotebook[], sd]]]}

To create a palette containing these buttons, evaluate the code to display the buttons then select them and use "Generate Palette from Selection" on the Palettes menu.