equation solving - Simplify not evaluating completely with Square roots

Here's a simple question. It's no longer high priority that I know this, but it's something that can come in handy later on.

Simplify[a > Sqrt[b]/c + d, a < Sqrt[b]/c + d]

or

Simplify[Sequence @@ ({a > n, a < n} /. {n ->  Sqrt[b]/c + d})]

or

n = Sqrt[b]/c + d;
Simplify[a > n, a < n]

all outputs:

Out: a > Sqrt[b]/c + d

while

Simplify[a > m, a < m]

outputs

Out: False

How come? This isn't an issue of not considering the negative root. The expressions are identical. As demonstrated by Simplify[a > m, a < m], replacing m with more complex expressions aside from having the Sqrt function.

In fact, if I use Surd, no matter the nth root, even or odd, or square root, Simplify will evaluate completely into False.

Why? Is this something that I can fix using Upvalues? -- Finally remember what the "overloading" feature was called.

Answer

The assumptions mechanism used by Simplify will not try to prove or disprove an inequality if the number of variables involved is higher than a built-in limit. To decide polynomial inequalities the assumptions mechanism uses the cylindrical algebraic decomposition algorithm, which has doubly-exponential complexity, hence the limit on the number of variables is low -- by default it is 4. Your inequality contains 5 polynomial variables, since to reduce it to a polynomial system we need to introduce a new variable v to replace Sqrt[b] and add an equation v^2==b.

The limit on the number of variables can be changed using a system option.

In[3]:= SetSystemOptions["SimplificationOptions"->"AssumptionsMaxNonlinearVariables"->5];

In[4]:= Simplify[a > Sqrt[b]/c + d, a < Sqrt[b]/c + d]
Out[4]= False