Syntax error: newline character interpreted as multiplication

I'm getting this error in Wolfram Workbench, and I don't know where it comes from: "Syntax error: newline character interpreted as multiplication"

This error happens around an If[] function, in a custom function, defined as

myFunction[x_,y_] :=

Module[{variable},


(* some code *)
variable = 1
If[x==2,x=3,x=4]

(* some code *)

]

No matter where I try to put my If[] function inside myFunction[], I get this error, but I don't get it if I put it outside myFunction[].

Maybe the problem comes from the Module[] function, as when I take it out the error disappears.

Any idea what's going on?

Answer

This is a very common error, and one I am guilty of making more often than I care to admit. The difficulty lies in how Mathematica determines where one expression ends and another begins, and how this interpretation seems to change within a construct like Module, Block, For, etc. In the following, I will primarily discuss how this applies to the front-end, but the conclusions are valid for WorkBench, too.

Consider the following examples:

p = 5; q = 6
DownValues[In]
(* { ...
     HoldPattern[In[7]] :> (p = 5; q = 6)
   ...}

*)

and

(r = 5;
 s = 6)
DownValues[In]
(* { ...
     HoldPattern[In[17]] :> (r = 5; s = 6)
   ...}
*)

versus

c = 5;
d = 6
DownValues[In]
(* { ...
     HoldPattern[In[4]] :> (c = 5;), HoldPattern[In[5]] :> (d = 6)
   ...}
*)

where I used the DownValues of In to show how Mathematica interprets the input lines. The first two examples are interpreted in exactly the same way as a single input line of code, but the third example produces two input lines. The key difference is that in the second example the carriage return is no longer interpreted as an input line delimiter because it is within an expression. Of course, this does not mean that

a
b

is interpreted as Times[a, b] as there is no obvious way to interpret the two as connected. Within parentheses or as a function parameter, the interpretation of the carriage-return as a input line delimiter is suspended, and it is treated as multiplication along with the rest of the whitespace characters.

The change in behavior from an input line delimiter to an implicit multiplication has an interesting consequence, the following generates an error

(l = 5
 m = 6)
DownValues[In]
(* 

   Set::write: "Tag Times in 5 m is Protected."
   { ...
     HoldPattern[In[14]] :> (l = 5 m = 6)
   ...}
*)

Looking at the FullForm of Hold[(l = 5 m = 6)] reveals

FullForm[Hold[(l = 5 m = 6)]]
(*
 Hold[Set[l, Set[Times[5, m], 6]]]

*)

telling us that we were trying to assign a value to Times. So, inside parentheses or as a function parameter, a semi-colon must be used to indicate that it is a compound expression.