performance tuning - Speeding up an intrinsically sequential operation

I am new to Mathematica and I am trying to measure its performance on a fundamentally sequential procedure.

1. 
   

   It involves a function STEP that operates on a List and returns an updated List.

   
   


2. 
   

   Therefore I use a NestList on this operation. The STEP operation involves a sequential calculation per each item in the List. There is no way to avoid this sequential operation without changing the problem.

   
   


3. 
   

   Each subsequent operation of STEP needs to use the latest List. In fact, it involves a matrix multiplication involving the latest List. I used a table and individual assignments to make this work.

   
   
   

I see no way of rewriting this code, at least easily, but I also see that a naive MATLAB implementation with two FOR loops produces code that is 4-5X faster on my laptop.

Below is a minimal code that shows what I am trying to do, it really slows down for larger NM and stepcount.

Am I missing something obvious?

Edit: The matrix shown below is not identically zero in general, one could think of it is any random matrix whose diagonals are zero. Here, it is a trivial example chosen to show the structure of the code.

ClearAll["Global`*"]
SeedRandom[1];
NM = 5;
minitial = 2 RandomInteger[{}, NM] - 1.;

Matrix = IdentityMatrix[5] 0;
stepcount = 10^2;
STEP[m_] := 
 Block[{md = m}, 
  Table[md[[i]] = 
    Sign[Tanh[Matrix[[i, All]].md + RandomReal[{-1, 1}]]], {i, NM}]; 
  md]
mm = (NestList[STEP[#] &, minitial, stepcount] + 1.)/2 // ArrayPlot

Edit: Just to clarify what I am trying to do, here is how it can be done in MATLAB. Please note that the for loops are unavoidable in this way of thinking.

for ii=1:NT
    for jj=1:NM
            I  = Matrix(jj,:)*m  
            m(jj) = sign (tanh[I]- rand(-1,1))
    end
      mm(:,ii)=m;
end

Maybe there is a more efficient way of doing this in Mathematica than how I implemented it. Hope this clarifies the problem.

Answer

Using Compile is a straightforward way to speed up procedural code based on machine numbers:

OP's:

SeedRandom[1];
NM = 50;
minitial = 2 RandomInteger[{}, NM] - 1.;
Matrix = IdentityMatrix[NM] 0;
stepcount = 10^4;
STEP[m_] := Block[{md = m}, 
   Table[md[[i]] = Sign[Tanh[Matrix[[i, All]].md + RandomReal[{-1, 1}]]],
    {i, NM}]];

mm1 = (NestList[STEP[#] &, minitial, stepcount] + 1.)/2; // AbsoluteTiming
(*  {1.4655, Null}  *)

Compiled:

cf = Compile[{{minitial, _Real, 1}, {Matrix, _Real, 
     2}, {stepcount, _Integer}},
   Block[{md = minitial},
    Rescale@Table[
      If[i == 0,  (* i = 0 probably isn't needed *)
       md[[j]],   (* except to conform with NestList *)

       md[[j]] = 
        Sign[Tanh[Matrix[[j, All]].md + RandomReal[{-1, 1}]]]
       ],
      {i, 0, stepcount}, {j, Length@minitial}]
    ](*, CompilationTarget -> "C"*)
   ];

SeedRandom[1];
NM = 50;
minitial = 2 RandomInteger[{}, NM] - 1.;

mm2 = cf[minitial, Matrix, stepcount]; // AbsoluteTiming
(*  {0.162614, Null}  *)

mm1 == mm2
(*  True  *)

Use CompilationTarget -> "C" and it speeds up by another factor of 2.