plotting - combining manipulate with "static" plot

Is there a way to show a plot of a "static" function as background for a manipulate panel ? In other words: I have put into a manipulate a trajectory (solution of a system of two differential equations):

solcontrol = 
FullSimplify[
  DSolve[{y'[t] == - y[t] - u z[t], 
          z'[t] == -1 -2 z[t] + u y[t], y[0] == 0, z[0] == -.5}, 
          {y[t], z[t]}, t]];

Then, I use Manipulate

{{ysol[t_], zsol[t_]}} = 
  Simplify[{y[t], z[t]} /. solcontrol, 
  Assumptions -> Element[u, Reals] && t > 0];

With[{y = ysol[t], z = zsol[t]}, 
   Manipulate[
    ParametricPlot[{y, z}, {t, 0, tend}], 
     {{tend, .1}, 0, 20},{{u, .7}, 0, 20}]]

Remark/problem:I'm using Mathematica 9 on a Debian. I don't know if you see the same manipulate panel as me on (say) Windows, but my panel sets its dimension "dynamically" respect on the form of trajectories.

Finally, my problem is to show the result of manipulate with this contour plot:

DeltaA[y_, z_] = -y^2 - z -2 z^2;
DeltaB[y_, z_] = -2 y z - y; 

ContourPlot[{DeltaA[y, z] == 0, DeltaB[y, z] == 0}, {y, -1,1},{z, -1, 1}]

because I want to see how trajectories behave respect the line of the plot.

thank you

Answer

enter image description here

Manipulate[
 Module[{sol, y, z, t},
  sol = First@DSolve[{y'[t] == -y[t] - u z[t], z'[t] == -1 - 2 z[t] + u y[t], 
       y[0] == 0, z[0] == -1/2}, {y[t], z[t]}, t];
  Show[p1, ParametricPlot[{y[t] /. sol, z[t] /. sol}, {t, 0, tend}]]
  ],
 {{tend, 5, "t"}, .1, 20, .1, Appearance -> "Labeled"},
 {{u, 10, "u"}, 0, 20, 1, Appearance -> "Labeled"},

 Initialization :>
  (
   deltaA[y_, z_] := -y^2 - z - 2 z^2;
   deltaB[y_, z_] := -2 y z - y;
   p1 = ContourPlot[{deltaA[y, z] == 0, deltaB[y, z] == 0}, {y, -1, 1}, {z, -1, 1},
        ContourStyle -> Red];
   )
 ]

Comments

plotting - Filling between two spheres in SphericalPlot3D

Manipulate[ SphericalPlot3D[{1, 2 - n}, {θ, 0, Pi}, {ϕ, 0, 1.5 Pi}, Mesh -> None, PlotPoints -> 15, PlotRange -> {-2.2, 2.2}], {n, 0, 1}] I cant' seem to be able to make a filling between two spheres. I've already tried the obvious Filling -> {1 -> {2}} but Mathematica doesn't seem to like that option. Is there any easy way around this or ... Answer There is no built-in filling in SphericalPlot3D . One option is to use ParametricPlot3D to draw the surfaces between the two shells: Manipulate[ Show[SphericalPlot3D[{1, 2 - n}, {θ, 0, Pi}, {ϕ, 0, 1.5 Pi}, PlotPoints -> 15, PlotRange -> {-2.2, 2.2}], ParametricPlot3D[{ r {Sin[t] Cos[1.5 Pi], Sin[t] Sin[1.5 Pi], Cos[t]}, r {Sin[t] Cos[0 Pi], Sin[t] Sin[0 Pi], Cos[t]}}, {r, 1, 2 - n}, {t, 0, Pi}, PlotStyle -> Yellow, Mesh -> {2, 15}]], {n, 0, 1}]

plotting - Plot 4D data with color as 4th dimension

I have a list of 4D data (x position, y position, amplitude, wavelength). I want to plot x, y, and amplitude on a 3D plot and have the color of the points correspond to the wavelength. I have seen many examples using functions to define color but my wavelength cannot be expressed by an analytic function. Is there a simple way to do this? Answer Here a another possible way to visualize 4D data: data = Flatten[Table[{x, y, x^2 + y^2, Sin[x - y]}, {x, -Pi, Pi,Pi/10}, {y,-Pi,Pi, Pi/10}], 1]; You can use the function Point along with VertexColors . Now the points are places using the first three elements and the color is determined by the fourth. In this case I used Hue, but you can use whatever you prefer. Graphics3D[ Point[data[[All, 1 ;; 3]], VertexColors -> Hue /@ data[[All, 4]]], Axes -> True, BoxRatios -> {1, 1, 1/GoldenRatio}]

plotting - Adding a thick curve to a regionplot

Suppose we have the following simple RegionPlot: f[x_] := 1 - x^2 g[x_] := 1 - 0.5 x^2 RegionPlot[{y < f[x], f[x] < y < g[x], y > g[x]}, {x, 0, 2}, {y, 0, 2}] Now I'm trying to change the curve defined by $y=g[x]$ into a thick black curve, while leaving all other boundaries in the plot unchanged. I've tried adding the region $y=g[x]$ and playing with the plotstyle, which didn't work, and I've tried BoundaryStyle, which changed all the boundaries in the plot. Now I'm kinda out of ideas... Any help would be appreciated! Answer With f[x_] := 1 - x^2 g[x_] := 1 - 0.5 x^2 You can use Epilog to add the thick line: RegionPlot[{y < f[x], f[x] < y < g[x], y > g[x]}, {x, 0, 2}, {y, 0, 2}, PlotPoints -> 50, Epilog -> (Plot[g[x], {x, 0, 2}, PlotStyle -> {Black, Thick}][[1]]), PlotStyle -> {Directive[Yellow, Opacity[0.4]], Directive[Pink, Opacity[0.4]],

Blog

Search This Blog