Skip to main content

export - How to apply `DiscretizeGraphics` to a tube?



I want to export the numerical solution of the Chan-Lee oscillator as an STL file so that I could print it out. But when I expanded the curve into a tube, DiscretizeGraphics recognizes it as an empty region. How could I somehow fill the tube and make it a discretizable solid?


My code:


α = 5; β = -10; δ = -.38;
s = NDSolve[{α x[t] - y[t] z[t] == 
 D[x[t], t], β y[t] + x[t] z[t] == 

 D[y[t], t], δ z[t] + x[t] y[t]/3 == D[z[t], t], 
x[0] == y[0] == z[0] == 10}, {x, y, z}, {t, 0, 100}, 
MaxSteps -> ∞];

ps = Table[{x[t] - y[t]/Sqrt[2], y[t], z[t]} /. First[s], {t, 0, 
100, .1}];
curve = Graphics3D[Tube[BSplineCurve[ps], .5]];

Export["Chan-Lee.stl", DiscretizeGraphics[curve]]

Answer




A possible workaround (brought up by the Wizard in the comments) involves the use of some of the functions from this previous answer. In particular, you will need orthogonalDirections[], extend[], and crossSection[] from that answer, along with these two additional functions for generating a suitable MeshRegion[] object:


MakeTriangleMesh[vl_List, opts___] := Module[{dims = Most[Dimensions[vl]]}, 
        MeshRegion[Apply[Join, vl], Triangle /@ Flatten[
                   Apply[{Append[Reverse[#1], Last[#2]], Prepend[#2, First[#1]]} &, 
                         Partition[Partition[Range[Times @@ dims], Last[dims]],
                                   {2, 2}, {1, 1}], {2}], 2], opts]] /; ArrayDepth[vl] == 3

TubeMesh[path_?MatrixQ, cs : (_Integer | _?MatrixQ), opts___] := 
    MakeTriangleMesh[FoldList[Function[{p, t}, With[{o = orthogonalDirections[t]},
                                       extend[#, t[[2]], t[[2]] - t[[1]], o] & /@ p]], 

                              crossSection[path, 1., cs],
                              Partition[path, 3, 1, {1, 2}, {}]], opts]

(The observant will notice that these are only slight modifications of the previous routines MakePolygons[] and TubePolygons[].)


For your specific example:


With[{α = 5, β = -10, δ = -.38},
     {xx, yy, zz} = NDSolveValue[{α x[t] - y[t] z[t] == x'[t],
                                  β y[t] + x[t] z[t] == y'[t],
                                  δ z[t] + x[t] y[t]/3 == z'[t],
                                  x[0] == y[0] == z[0] == 10}, {x, y, z}, {t, 0, 100}]]


path = Transpose[{{1/Sqrt[2], -1/Sqrt[2], 0}, {0, 1, 0}, {0, 0, 1}} .
                 Through[{xx, yy, zz}["ValuesOnGrid"]]];

TubeMesh[path, CirclePoints[0.5, 20]]

a meshed tube


Note that the result is an open tube (equivalent to using CapForm[None] with Tube[]); the equivalent of using CapForm["Round"] is slightly trickier to do.


Comments

Post a Comment

Popular posts from this blog

functions - Get leading series expansion term?

Given a function f[x] , I would like to have a function leadingSeries that returns just the leading term in the series around x=0 . For example: leadingSeries[(1/x + 2)/(4 + 1/x^2 + x)] x and leadingSeries[(1/x + 2 + (1 - 1/x^3)/4)/(4 + x)] -(1/(16 x^3)) Is there such a function in Mathematica? Or maybe one can implement it efficiently? EDIT I finally went with the following implementation, based on Carl Woll 's answer: lds[ex_,x_]:=( (ex/.x->(x+O[x]^2))/.SeriesData[U_,Z_,L_List,Mi_,Ma_,De_]:>SeriesData[U,Z,{L[[1]]},Mi,Mi+1,De]//Quiet//Normal) The advantage is, that this one also properly works with functions whose leading term is a constant: lds[Exp[x],x] 1 Answer Update 1 Updated to eliminate SeriesData and to not return additional terms Perhaps you could use: leadingSeries[expr_, x_] := Normal[expr /. x->(x+O[x]^2) /. a_List :> Take[a, 1]] Then for your examples: leadingSeries[(1/x + 2)/(4 + 1/x^2 + x), x] leadingSeries[Exp[x], x] leadingSeries[(1/x + 2 + (1 - 1/x...
Post a Comment
Read more

How to thread a list

I have data in format data = {{a1, a2}, {b1, b2}, {c1, c2}, {d1, d2}} Tableform: I want to thread it to : tdata = {{{a1, b1}, {a2, b2}}, {{a1, c1}, {a2, c2}}, {{a1, d1}, {a2, d2}}} Tableform: And I would like to do better then pseudofunction[n_] := Transpose[{data2[[1]], data2[[n]]}]; SetAttributes[pseudofunction, Listable]; Range[2, 4] // pseudofunction Here is my benchmark data, where data3 is normal sample of real data. data3 = Drop[ExcelWorkBook[[Column1 ;; Column4]], None, 1]; data2 = {a #, b #, c #, d #} & /@ Range[1, 10^5]; data = RandomReal[{0, 1}, {10^6, 4}]; Here is my benchmark code kptnw[list_] := Transpose[{Table[First@#, {Length@# - 1}], Rest@#}, {3, 1, 2}] &@list kptnw2[list_] := Transpose[{ConstantArray[First@#, Length@# - 1], Rest@#}, {3, 1, 2}] &@list OleksandrR[list_] := Flatten[Outer[List, List@First[list], Rest[list], 1], {{2}, {1, 4}}] paradox2[list_] := Partition[Riffle[list[[1]], #], 2] & /@ Drop[list, 1] RM[list_] := FoldList[Transpose[{First@li...
Post a Comment
Read more

front end - keyboard shortcut to invoke Insert new matrix

I frequently need to type in some matrices, and the menu command Insert > Table/Matrix > New... allows matrices with lines drawn between columns and rows, which is very helpful. I would like to make a keyboard shortcut for it, but cannot find the relevant frontend token command (4209405) for it. Since the FullForm[] and InputForm[] of matrices with lines drawn between rows and columns is the same as those without lines, it's hard to do this via 3rd party system-wide text expanders (e.g. autohotkey or atext on mac). How does one assign a keyboard shortcut for the menu item Insert > Table/Matrix > New... , preferably using only mathematica? Thanks! Answer In the MenuSetup.tr (for linux located in the $InstallationDirectory/SystemFiles/FrontEnd/TextResources/X/ directory), I changed the line MenuItem["&New...", "CreateGridBoxDialog"] to read MenuItem["&New...", "CreateGridBoxDialog", MenuKey["m", Modifiers-...
Post a Comment
Read more