graphics - BarChart that lines up with dates in DateListPlot

I am trying to create a chart similar to the view offered by TradingChart, but with custom data not relating to finance.

allData = {{"2014-03-31", 91.0657, 91.5555, Null, 79.4144, 90.0735, 86.9567, 87.1578, 79},
           {"2014-04-06", Null, 90.9839, 85.0053, 79.2423, 87.7565, 85.0126, Null, 108},
           {"2014-04-22", 90.9086, 90.9959, Null, 78.9365, 87.5949, 86.1197, Null, 93},
           {"2014-04-28", 92.3299, 92.068, Null, 79.7057, 90.187, 86.4088, Null, 98}}

I am using the first column as a date marker, the last column as a volume counter, and the remaining columns as data for the line graph. I should be clear that the size of these data sets are flexible. There may be more or fewer dates and there may be more or fewer columns for lines. I clean up the data a little then place it into a DateListPlot (on the actual plots I have included a legend and better markers, but that is not so important here):

temp = Drop[allData, None, {-1}];

lineData = {};
For[i = 2, i < Length @ temp[[1]], i++,
    AppendTo[lineData, Transpose[{temp[[;; , 1]], temp[[;; , i]]}]]
];

DateListPlot[lineData, 
    Joined -> True,

    PlotStyle -> Thick, 
    ImageSize -> Scaled[0.75], 
    PlotMarkers -> Automatic ,
    PlotRange -> {Automatic, {70, 100}}
]

Here is the output:

Graph

As you can see the data is sporadic. Some dates have no entries at all, some columns have Null values. It seems Mma is having some trouble with the sparse data. Ideally the lines would pass straight through to the next non-null entry, so some help with doing that would be appreciated.

But the main question I have is with regards to putting a bar chart underneath this that matches up with the dates and uses the last column of allData as the volume. It is not clear if there is any way to do this with Histogram or with BarChart and I am not so experienced with Mma to know if I have to do this with Graphics primitives.

Eventually I would like to add some interactivity, which is what drew me to the TradingChart:

CountBars

Answer

There is a very quick way to arrive at this. If you are new to Mathematica then maybe this is a starting point.

lineData = {allData[[All, {1, 2}]], allData[[All, {1, 3}]], 
  allData[[All, {1, 4}]], allData[[All, {1, 5}]], 
  allData[[All, {1, 6}]], allData[[All, {1, 7}]]}

volume = allData[[All, {1, -1}]]


p1 = DateListPlot[lineData, Joined -> True, PlotStyle -> Thick, 
  ImageSize -> Scaled[0.75], PlotMarkers -> Automatic, 
  PlotRange -> {Automatic, {70, 100}}];

p2 = DateListPlot[volume, AspectRatio -> 0.15, Joined -> False, 
  Filling -> 0, 
  FillingStyle -> 
   Directive[CapForm["Butt"], AbsoluteThickness[20], Blue], 
  PlotStyle -> None, ImageSize -> Scaled[0.75], PlotMarkers -> None, 
  PlotRange -> {Automatic, {0,Automatic}}];


Column[{p1, p2}]

enter image description here

There is a lot more you can do with this. For example to mimic the trading chart you may want to remove frame ticks on the bottom of p2 and add GridLines -> Automatic, GridLinesStyle -> Dotted to both plots. For regular use you will probably need to specify identical ImagePaddingin each plot to ensure that they line up. But this is a easy way to implement "on the run".

plotting - Filling between two spheres in SphericalPlot3D

Manipulate[ SphericalPlot3D[{1, 2 - n}, {θ, 0, Pi}, {ϕ, 0, 1.5 Pi}, Mesh -> None, PlotPoints -> 15, PlotRange -> {-2.2, 2.2}], {n, 0, 1}] I cant' seem to be able to make a filling between two spheres. I've already tried the obvious Filling -> {1 -> {2}} but Mathematica doesn't seem to like that option. Is there any easy way around this or ... Answer There is no built-in filling in SphericalPlot3D . One option is to use ParametricPlot3D to draw the surfaces between the two shells: Manipulate[ Show[SphericalPlot3D[{1, 2 - n}, {θ, 0, Pi}, {ϕ, 0, 1.5 Pi}, PlotPoints -> 15, PlotRange -> {-2.2, 2.2}], ParametricPlot3D[{ r {Sin[t] Cos[1.5 Pi], Sin[t] Sin[1.5 Pi], Cos[t]}, r {Sin[t] Cos[0 Pi], Sin[t] Sin[0 Pi], Cos[t]}}, {r, 1, 2 - n}, {t, 0, Pi}, PlotStyle -> Yellow, Mesh -> {2, 15}]], {n, 0, 1}]

plotting - Plot 4D data with color as 4th dimension

I have a list of 4D data (x position, y position, amplitude, wavelength). I want to plot x, y, and amplitude on a 3D plot and have the color of the points correspond to the wavelength. I have seen many examples using functions to define color but my wavelength cannot be expressed by an analytic function. Is there a simple way to do this? Answer Here a another possible way to visualize 4D data: data = Flatten[Table[{x, y, x^2 + y^2, Sin[x - y]}, {x, -Pi, Pi,Pi/10}, {y,-Pi,Pi, Pi/10}], 1]; You can use the function Point along with VertexColors . Now the points are places using the first three elements and the color is determined by the fourth. In this case I used Hue, but you can use whatever you prefer. Graphics3D[ Point[data[[All, 1 ;; 3]], VertexColors -> Hue /@ data[[All, 4]]], Axes -> True, BoxRatios -> {1, 1, 1/GoldenRatio}]

plotting - Adding a thick curve to a regionplot

Suppose we have the following simple RegionPlot: f[x_] := 1 - x^2 g[x_] := 1 - 0.5 x^2 RegionPlot[{y < f[x], f[x] < y < g[x], y > g[x]}, {x, 0, 2}, {y, 0, 2}] Now I'm trying to change the curve defined by $y=g[x]$ into a thick black curve, while leaving all other boundaries in the plot unchanged. I've tried adding the region $y=g[x]$ and playing with the plotstyle, which didn't work, and I've tried BoundaryStyle, which changed all the boundaries in the plot. Now I'm kinda out of ideas... Any help would be appreciated! Answer With f[x_] := 1 - x^2 g[x_] := 1 - 0.5 x^2 You can use Epilog to add the thick line: RegionPlot[{y < f[x], f[x] < y < g[x], y > g[x]}, {x, 0, 2}, {y, 0, 2}, PlotPoints -> 50, Epilog -> (Plot[g[x], {x, 0, 2}, PlotStyle -> {Black, Thick}][[1]]), PlotStyle -> {Directive[Yellow, Opacity[0.4]], Directive[Pink, Opacity[0.4]],

Blog

Search This Blog