differential equations - Piecewise Function within NDSolve

So I am quite new to Mathematica and programming in general and I am running into an issue while trying to use the numerical diff eq solver (NDSolve) within mathematica. This is what my code looks like:

 NDSolve[
 {Paorta'[t] == (1/
    Caorta)[(Pheart[t] - Paorta[t])/
     Piecewise[{{Ro, Pheart[t] - Paorta[t] > 0}, {x*Ro, 
        Pheart[t] - Paorta[t] < 0}}, .25] - Paorta[t]/Rsystemic], 

  Paorta[0] == 120},
 {Paorta[t]},
 {t, 0, 6}
 ]

Now, I am getting the error "NDSolve::ndnum: Encountered non-numerical value for a derivative at t == 0.

I am pretty sure the reason for this is the fact that I have the function I am trying to solve for as one of the conditions in the piecewise function but I need that to be there for the purposes of the project I am working on.

Is there any way to get around this issue? And is this even what is causing my issue?

These are the definitions I have used previously in the code:

Ro = .25;

Caorta = 1/.48;
k = 110;
\[Omega] = 2 \[Pi];
x = 8000;
Pheart[t_] :=  1/2*k*(1 + Cos[\[Omega] t]) + 10 ;
Rsystemic = 3.1;

Thanks in advance, Dinomite

Answer

Your main problem is a stray pair of square brackets [] in the argument of NDSolve. Square brackets have special meaning in Mathematica, so they cannot be used to group expressions and to alter the evaluation order. To accomplish the latter, you always use () instead.

Your Piecewise function definition was also possibly more complicated than it needed to be. Since you really have only two definitions, you can use the one in the conditional definition, and use the other as the default value. This seems to take care of another complaint that NDSolve would display otherwise.

In short:

NDSolve[{
  Paorta'[t] == 
      (1/Caorta) ( (Pheart[t] - Paorta[t]) / 
       Piecewise[{{Ro, Pheart[t] - Paorta[t] > 0}}, x*Ro] - Paorta[t]/Rsystemic ),
  Paorta[0] == 120
  },
 Paorta, {t, 0, 6}
]


Plot[Paorta[t] /. %, {t, 0, 6}, Evaluated -> True]