front end - how to get the Messages Tab back in version 11.1 Edit->Preferences?

On windows 7, version 11.1, when doing edit->Preferences, no longer has the very nice messages tab there any more. I searched but so far, not able to find this tab.

So can't change where my Print output go to easily as before, and change other similar settings.

Is it possible to get this tab back? If not, is there other easy way to make same changes? I really do not want to go through advanced setting and go search option inspector and edit things each time I want to make such changes, since I used to change these settings all the time.

Answer

I don't know why but:

[...] Unfortunately removing the Evaluation and Messages tabs in Mathematica 11.1 Preferences is by design. However those settings can be found in our Option Inspector: [...]

Here is an official documentation about that issue:

---

You can use old preferences dialog but I can't guarantee everything will be fine:

Module[{relPath, newPath, oldVersion = "11.0"}

  , relPath = Sequence[
        "SystemFiles", "FrontEnd", "SystemResources", "Preferences.nb"
    ]

  ; newPath = FileNameJoin[{$UserBaseDirectory, relPath}]

  ; If[
        Not @ DirectoryQ @ #
      , CreateDirectory[#, CreateIntermediateDirectories -> True]
    ] & @ DirectoryName @ newPath


  ; CopyFile[
        FileNameJoin[{FileNameDrop @ $InstallationDirectory, oldVersion, relPath}]
      , newPath
    ]

]

It copies old dialog to the latest $UserBaseDirectory so you don't need to do backup. Just go and delete newPath file if anything is wrong.

---

Another way is to play with those options programmatically:

CurrentValue[$FrontEnd, PrintAction]

"PrintToConsole"

Options[$FrontEnd, MessageOptions]

{MessageOptions -> {"AllowDisablingWarnings" -> True, 

   "CodeCaptionWarning" -> True, "CompatibilityToolWarning" -> True, 
   "ConsoleMessageAction" -> "PrintToConsole", 
   "ErrorAction" -> "PrintToConsole", "ExplainBeepHelp" -> False, 
   "IgnoreTagBoxDeletionWarning" -> True, 
   "InsufficientVersionWarning" -> True, 
   "KernelMessageAction" -> "PrintToConsole", 
   "MathMLPasteWarning" -> True, "MaxMessageCount" -> 3, 
   "MessageCountResetTime" -> 2., "TeXPasteWarning" -> True, 
   "TraditionalFormEvaluationWarning" -> True, 
   "UseVersionedStylesheetWarning" -> True, 

   "WarningAction" -> "Beep"}}

You can set them e.g.:

CurrentValue[$FrontEnd, {"MessageOptions", "KernelMessageAction"}] = 
    {"PrintToConsole", "Beep"}