plotting - Getting a correct custom legend for contourplot?

I am having trouble making a custom range for a legend in ContourPlot since the legend doesn't "talk" to the PlotRange and adjust its scale accordingly. How do I go about fixing this?

As an explicit example consider the following. If I run ContourPlot with an automatic legend I get the right scaling:

 ContourPlot[x y , {x, 0, 2}, {y, 0, 2}, PlotLegends->Automatic,

ColorFunction ->"BlueGreenYellow"]

enter image description here

But if I use a custom legend range then the legend no longer corresponds to the image:

ContourPlot[x y , {x, 0, 2}, {y, 0, 2},
PlotLegends -> BarLegend[{"BlueGreenYellow", {0, 10}}]

enter image description here

How do I get the plot to use the same scale as the legend?

Answer

This was more involved than I expected. First, you need to set the ColorFunction to encompass the full range,

ColorData[{"BlueGreenYellow", {0, 10}}]

Interestingly, I did not know about that form of ColorData until earlier this week, so I recommend reading through the Details section closely. Now, to use this within ContourPlot, you need to set

ColorFunctionScaling -> False

otherwise ContourPlot will rescale everything. As to the legend, you need to specify both the contour range, like you were doing, and the number of contours to force it to use the range correctly,

BarLegend[{Automatic, {0, 10}}, 20]

Note the use of Automatic, the color function is automatically passed to the legend, so you do not to add it again. The range is necessary because the legend is only passed the range present in the plot itself. Lastly, the number of contours has to be large enough for BarLegend to use the full range, and 20 works here. All together, this is

ContourPlot[x y, {x, 0, 2}, {y, 0, 2},
  PlotLegends -> BarLegend[{Automatic, {0, 10}}, 20], 
  ColorFunction -> ColorData[{"BlueGreenYellow", {0, 10}}],
  ColorFunctionScaling -> False
]

enter image description here

Comments

plotting - Filling between two spheres in SphericalPlot3D

Manipulate[ SphericalPlot3D[{1, 2 - n}, {θ, 0, Pi}, {ϕ, 0, 1.5 Pi}, Mesh -> None, PlotPoints -> 15, PlotRange -> {-2.2, 2.2}], {n, 0, 1}] I cant' seem to be able to make a filling between two spheres. I've already tried the obvious Filling -> {1 -> {2}} but Mathematica doesn't seem to like that option. Is there any easy way around this or ... Answer There is no built-in filling in SphericalPlot3D . One option is to use ParametricPlot3D to draw the surfaces between the two shells: Manipulate[ Show[SphericalPlot3D[{1, 2 - n}, {θ, 0, Pi}, {ϕ, 0, 1.5 Pi}, PlotPoints -> 15, PlotRange -> {-2.2, 2.2}], ParametricPlot3D[{ r {Sin[t] Cos[1.5 Pi], Sin[t] Sin[1.5 Pi], Cos[t]}, r {Sin[t] Cos[0 Pi], Sin[t] Sin[0 Pi], Cos[t]}}, {r, 1, 2 - n}, {t, 0, Pi}, PlotStyle -> Yellow, Mesh -> {2, 15}]], {n, 0, 1}]

plotting - Plot 4D data with color as 4th dimension

I have a list of 4D data (x position, y position, amplitude, wavelength). I want to plot x, y, and amplitude on a 3D plot and have the color of the points correspond to the wavelength. I have seen many examples using functions to define color but my wavelength cannot be expressed by an analytic function. Is there a simple way to do this? Answer Here a another possible way to visualize 4D data: data = Flatten[Table[{x, y, x^2 + y^2, Sin[x - y]}, {x, -Pi, Pi,Pi/10}, {y,-Pi,Pi, Pi/10}], 1]; You can use the function Point along with VertexColors . Now the points are places using the first three elements and the color is determined by the fourth. In this case I used Hue, but you can use whatever you prefer. Graphics3D[ Point[data[[All, 1 ;; 3]], VertexColors -> Hue /@ data[[All, 4]]], Axes -> True, BoxRatios -> {1, 1, 1/GoldenRatio}]

plotting - Adding a thick curve to a regionplot

Suppose we have the following simple RegionPlot: f[x_] := 1 - x^2 g[x_] := 1 - 0.5 x^2 RegionPlot[{y < f[x], f[x] < y < g[x], y > g[x]}, {x, 0, 2}, {y, 0, 2}] Now I'm trying to change the curve defined by $y=g[x]$ into a thick black curve, while leaving all other boundaries in the plot unchanged. I've tried adding the region $y=g[x]$ and playing with the plotstyle, which didn't work, and I've tried BoundaryStyle, which changed all the boundaries in the plot. Now I'm kinda out of ideas... Any help would be appreciated! Answer With f[x_] := 1 - x^2 g[x_] := 1 - 0.5 x^2 You can use Epilog to add the thick line: RegionPlot[{y < f[x], f[x] < y < g[x], y > g[x]}, {x, 0, 2}, {y, 0, 2}, PlotPoints -> 50, Epilog -> (Plot[g[x], {x, 0, 2}, PlotStyle -> {Black, Thick}][[1]]), PlotStyle -> {Directive[Yellow, Opacity[0.4]], Directive[Pink, Opacity[0.4]],

Blog

Search This Blog