Skip to main content

simplifying expressions - Using Hold correctly with Simplify and ComplexityFunction


It seems like Mathematica immediately evaluates the expression Sqrt@I to (-1)^(1/4). I'm trying to use Simplify with my own ComplexityFunction f in such a way, that Simplify[Sqrt@I] returns Sqrt@I, which (in my opinion) is the simpler expression. Hence, I've defined the following f:


Attributes[f]=HoldAll;
f[expr_]:=StringLength@ToString@HoldForm@expr

Testing it yields the expected results:


f[Sqrt@I]
f[(-1)^(1/4)]



7


12



Now, when I call Simplify[Sqrt@I, ComplexityFunction->f] it still returns (-1)^(1/4). I believe this is due to the fact that after the simplification (which should return Sqrt@I), the expression is in turn evaluated to (-1)^(1/4). Can I define f in such a way that this last evaluation is not performed? Can I use HoldForm to achieve this?



Answer



I believe your function works correctly but the automatic transformation functions used by Simplify lack a rule that converts (-1)^(1/4) into Sqrt[I]. Also, your observation that the reverse transformation happens automatically is correct, therefore even with the right transformation function you do not get the result you want. However, you can Hold the expression to prevent this.


Attributes[f] = HoldAll;
f[expr_] := StringLength @ ToString @ HoldForm @ expr


tf = # /. HoldPattern[(-1)^(1/4)] :> Sqrt @ I &;

Simplify[Hold[(-1)^(1/4)], ComplexityFunction -> f, TransformationFunctions -> tf]


Hold[Sqrt[I]]

I used a transformation rule that explicitly performs the replacement you desire. It also operates inside of Hold which the default transformations do not. This isn't particuarly helpful I fear but it does illustrate that with the right ComplexityFunction and TransformationFunctions settings Simplify can perform the operation you want. Crafting those functions may be difficult however.



I took another look at this, and it seems that the custom ComplexityFunction is not needed here. I also found that (-1)^(1/4) may be represented in at least two different internal forms which illustrates the complexity of crafting your own rules. (In practice if any transformations can be done with built-in functions rather than manual pattern matching they should be done that way.)



auto = Replace[#, x_ :> With[{eval = FullSimplify[x]}, eval /; True], -1] &;
tf = # /. HoldPattern[(-1)^(1/4) | (-1)^Rational[1, 4]] :> Sqrt[I] &;

expr = Hold[1/(3 (1 + x)) - (-1 + 2 x)/(6 (1 - x + x^2)) +
            2/(3 (1 + 1/3 (-1 + 2 x)^2)) + (-1)^(1/4)];

Simplify[expr, TransformationFunctions -> {auto, tf}]


Hold[Sqrt[I] + 1/(1 + x^3)]


Notice that in the rule auto I am calling FullSimplify to access the default rules, and I am using the Trott-Strzebonski method for In-Place Evaluation to make these apply inside Hold.


Comments

Post a Comment

Popular posts from this blog

mathematical optimization - Minimizing using indices, error: Part::pkspec1: The expression cannot be used as a part specification

I want to use Minimize where the variables to minimize are indices pointing into an array. Here a MWE that hopefully shows what my problem is. vars = u@# & /@ Range[3]; cons = Flatten@ { Table[(u[j] != #) & /@ vars[[j + 1 ;; -1]], {j, 1, 3 - 1}], 1 vec1 = {1, 2, 3}; vec2 = {1, 2, 3}; Minimize[{Total@((vec1[[#]] - vec2[[u[#]]])^2 & /@ Range[1, 3]), cons}, vars, Integers] The error I get: Part::pkspec1: The expression u[1] cannot be used as a part specification. >> Answer Ok, it seems that one can get around Mathematica trying to evaluate vec2[[u[1]]] too early by using the function Indexed[vec2,u[1]] . The working MWE would then look like the following: vars = u@# & /@ Range[3]; cons = Flatten@{ Table[(u[j] != #) & /@ vars[[j + 1 ;; -1]], {j, 1, 3 - 1}], 1 vec1 = {1, 2, 3}; vec2 = {1, 2, 3}; NMinimize[ {Total@((vec1[[#]] - Indexed[vec2, u[#]])^2 & /@ R...
Post a Comment
Read more

functions - Get leading series expansion term?

Given a function f[x] , I would like to have a function leadingSeries that returns just the leading term in the series around x=0 . For example: leadingSeries[(1/x + 2)/(4 + 1/x^2 + x)] x and leadingSeries[(1/x + 2 + (1 - 1/x^3)/4)/(4 + x)] -(1/(16 x^3)) Is there such a function in Mathematica? Or maybe one can implement it efficiently? EDIT I finally went with the following implementation, based on Carl Woll 's answer: lds[ex_,x_]:=( (ex/.x->(x+O[x]^2))/.SeriesData[U_,Z_,L_List,Mi_,Ma_,De_]:>SeriesData[U,Z,{L[[1]]},Mi,Mi+1,De]//Quiet//Normal) The advantage is, that this one also properly works with functions whose leading term is a constant: lds[Exp[x],x] 1 Answer Update 1 Updated to eliminate SeriesData and to not return additional terms Perhaps you could use: leadingSeries[expr_, x_] := Normal[expr /. x->(x+O[x]^2) /. a_List :> Take[a, 1]] Then for your examples: leadingSeries[(1/x + 2)/(4 + 1/x^2 + x), x] leadingSeries[Exp[x], x] leadingSeries[(1/x + 2 + (1 - 1/x...
Post a Comment
Read more

What is and isn't a valid variable specification for Manipulate?

I have an expression whose terms have arguments (representing subscripts), like this: myExpr = A[0] + V[1,T] I would like to put it inside a Manipulate to see its value as I move around the parameters. (The goal is eventually to plot it wrt one of the variables inside.) However, Mathematica complains when I set V[1,T] as a manipulated variable: Manipulate[Evaluate[myExpr], {A[0], 0, 1}, {V[1, T], 0, 1}] (*Manipulate::vsform: Manipulate argument {V[1,T],0,1} does not have the correct form for a variable specification. >> *) As a workaround, if I get rid of the symbol T inside the argument, it works fine: Manipulate[ Evaluate[myExpr /. T -> 15], {A[0], 0, 1}, {V[1, 15], 0, 1}] Why this behavior? Can anyone point me to the documentation that says what counts as a valid variable? And is there a way to get Manpiulate to accept an expression with a symbolic argument as a variable? Investigations I've done so far: I tried using variableQ from this answer , but it says V[1...
Post a Comment
Read more