Skip to main content

gui construction - Problems with visual update in GUI


Consider the following. When clicking in "Browse" and then choosing a file, the path will remain the original one and won't change to the one of the file I chose:


nb = EvaluationNotebook[];

DynamicModule[
 {path1 = FileNameJoin[{$HomeDirectory, "Desktop", "file.nb"}],
  path2 = FileNameJoin[{$HomeDirectory, "Desktop", "file.xls"}]}, 

 CreateDialog[
  Column[{Row[{InputField[Dynamic[path1], String, Enabled -> False], 
      FileNameSetter[Dynamic[path1], 
       "Open", {"Mathematica Notebook" -> {"*.nb"}}]}], 
    Row[{InputField[Dynamic[path2], String, Enabled -> False], 
      FileNameSetter[Dynamic[path2], 
       "Open", {"Excel files" -> {"*.xls", "*.xlsx"}}]}]}], 
  NotebookEventActions :> {"WindowClose" :> (SetOptions[nb, 
       Visible -> True])}]
]


Answer



The behaviour is indeed inconsistent: CreateDialog uses the option WindowSize -> All, where All (god knows why) causes the unexpected behaviour with dynamic content. See resolution of the problem at the end of the post.


The following even more simple example clearly shows that something fishy is going on: only path2 can be set via the second button but not path1:


DynamicModule[{path1 = "path #1", path2 = "path #2"},
  CreateDialog@Grid@{
     {FileNameSetter[Dynamic@path1, 
       "Open", {"Mathematica Notebook" -> {"*.nb"}}], Dynamic@path1},
     {FileNameSetter[Dynamic@path2, 
       "Open", {"Excel files" -> {"*.xls", "*.xlsx"}}], Dynamic@path2}
     }];


Removing the CreateDialog wrapper causes both FileNameSetters to work as expected, which indicates that it is the special context of the dialog window that causes the erroneous behaviour. Since CreateDialog[expr] is just a specialized CreateWindow[DocumentNotebook[expr]], we have to look at the options CreateDialog uses as defaults for its internal CreateWindow. As it turns out, the blame lies with WindowSize. Compare the behavior of the following two examples where only the value of WindowSize differs.


This is faulty:


DynamicModule[{path1 = "path #1", path2 = "path #2"},
 CreateWindow[DocumentNotebook@Grid@{
     {FileNameSetter[Dynamic@path1, 
       "Open", {"Mathematica Notebook" -> {"*.nb"}}], Dynamic@path1},
     {FileNameSetter[Dynamic@path2, 
       "Open", {"Excel files" -> {"*.xls", "*.xlsx"}}], Dynamic@path2}
     }, WindowSize -> All]]


This works as expected:


DynamicModule[{path1 = "path #1", path2 = "path #2"},
 CreateWindow[DocumentNotebook@Grid@{
     {FileNameSetter[Dynamic@path1, 
       "Open", {"Mathematica Notebook" -> {"*.nb"}}], Dynamic@path1},
     {FileNameSetter[Dynamic@path2, 
       "Open", {"Excel files" -> {"*.xls", "*.xlsx"}}], Dynamic@path2}
     }, WindowSize -> {200, 200}]]


And then I remembered: Strange behavior of CreateDialog in (Dynamic)Module


The options for CreateWindow (to make it look like it is a dialog) are:


{WindowSize -> {200, 200}, Deployed -> True, ShowCellBracket -> False,
 WindowFloating -> False, StyleDefinitions -> "Dialog.nb",
 WindowFrame -> "ModelessDialog"}

Comments

Post a Comment

Popular posts from this blog

plotting - Plot 4D data with color as 4th dimension

I have a list of 4D data (x position, y position, amplitude, wavelength). I want to plot x, y, and amplitude on a 3D plot and have the color of the points correspond to the wavelength. I have seen many examples using functions to define color but my wavelength cannot be expressed by an analytic function. Is there a simple way to do this? Answer Here a another possible way to visualize 4D data: data = Flatten[Table[{x, y, x^2 + y^2, Sin[x - y]}, {x, -Pi, Pi,Pi/10}, {y,-Pi,Pi, Pi/10}], 1]; You can use the function Point along with VertexColors . Now the points are places using the first three elements and the color is determined by the fourth. In this case I used Hue, but you can use whatever you prefer. Graphics3D[ Point[data[[All, 1 ;; 3]], VertexColors -> Hue /@ data[[All, 4]]], Axes -> True, BoxRatios -> {1, 1, 1/GoldenRatio}]
Post a Comment
Read more

plotting - Filling between two spheres in SphericalPlot3D

Manipulate[ SphericalPlot3D[{1, 2 - n}, {θ, 0, Pi}, {ϕ, 0, 1.5 Pi}, Mesh -> None, PlotPoints -> 15, PlotRange -> {-2.2, 2.2}], {n, 0, 1}] I cant' seem to be able to make a filling between two spheres. I've already tried the obvious Filling -> {1 -> {2}} but Mathematica doesn't seem to like that option. Is there any easy way around this or ... Answer There is no built-in filling in SphericalPlot3D . One option is to use ParametricPlot3D to draw the surfaces between the two shells: Manipulate[ Show[SphericalPlot3D[{1, 2 - n}, {θ, 0, Pi}, {ϕ, 0, 1.5 Pi}, PlotPoints -> 15, PlotRange -> {-2.2, 2.2}], ParametricPlot3D[{ r {Sin[t] Cos[1.5 Pi], Sin[t] Sin[1.5 Pi], Cos[t]}, r {Sin[t] Cos[0 Pi], Sin[t] Sin[0 Pi], Cos[t]}}, {r, 1, 2 - n}, {t, 0, Pi}, PlotStyle -> Yellow, Mesh -> {2, 15}]], {n, 0, 1}]
Post a Comment
Read more

plotting - Mathematica: 3D plot based on combined 2D graphs

I have several sigmoidal fits to 3 different datasets, with mean fit predictions plus the 95% confidence limits (not symmetrical around the mean) and the actual data. I would now like to show these different 2D plots projected in 3D as in but then using proper perspective. In the link here they give some solutions to combine the plots using isometric perspective, but I would like to use proper 3 point perspective. Any thoughts? Also any way to show the mean points per time point for each series plus or minus the standard error on the mean would be cool too, either using points+vertical bars, or using spheres plus tubes. Below are some test data and the fit function I am using. Note that I am working on a logit(proportion) scale and that the final vertical scale is Log10(percentage). (* some test data *) data = Table[Null, {i, 4}]; data[[1]] = {{1, -5.8}, {2, -5.4}, {3, -0.8}, {4, -0.2}, {5, 4.6}, {1, -6.4}, {2, -5.6}, {3, -0.7}, {4, 0.04}, {5, 1.0}, {1, -6.8}, {2, -4.7}, {3, -1....
Post a Comment
Read more