Skip to main content

graphics - Using Manipulate with a control variable for selective recalculation


I'm trying to adapt Nasser's method for using a control variable inside Manipulate to selectively choose what part of the code should be recalculated depending on the controls changed. I've also read his previous notes but the last version seems much more simple and something I can follow.


I need this functionality for a simulation I'm working on about the field lines of an electric dipole.


In the simulation it should be possible to move the two charges q1 and q2 generating the field and also to move a third point P. The point P only serves to see the field line passing through P.


Since the single field line originating from P should have different graphical parameters than the field lines of the "background field" I created two different Streamplots: "fieldlines" is for the general field and "fieldpoint" is for the single line through P. They are combined together with the "Show" command.


So my problem is similar to the one addressed in the first link. If I move the point P I don't want the Streamplot fieldlines of the electric field lines recalculated, but just the Streamplot fieldpoint (dealing with the single line through P). On the contrary both Streamplots should be recalculated when the two charges generating the field are moved or changed.


Up to now, following Nasser's model I've come up with the following "example" code (my intended simulation is much more complicated):



Manipulate[tick;
 Show[f1, f2],
 Grid[{
   {"q1pos", 
    Slider2D[
     Dynamic[q1pos, {q1pos = #; f1 = fieldlines[q1pos, q2pos]; 
        f2 = fieldpoint[q1pos, q2pos, pt];
        tick = Not[tick]} &], {{-6, -6}, {6, 6}}], Dynamic[q1pos]},
   {"q2pos", 
    Slider2D[

     Dynamic[q2pos, {q2pos = #; f1 = fieldlines[q1pos, q2pos]; 
        f2 = fieldpoint[q1pos, q2pos, pt];
        tick = Not[tick]} &], {{-6, -6}, {6, 6}}], 
    Dynamic[q2pos]}, {"pt", 
    Slider2D[Dynamic[pt, {pt = #; f2 = fieldpoint[q1pos, q2pos, pt];
        tick = Not[tick]} &], {{-6, -6}, {6, 6}}], Dynamic[pt]}
   }],
 {{tick, False}, None},
 {{q1pos, {-2, 0}}, None},
 {{q2pos, {2, 0}}, None},

 {{pt, {-2.5, 2}}, None},
 {{f1, fieldlines[{-2, 0}, {2, 0}]}, None},
 {{f2, fieldpoint[{-2, 0}, {2, 0}, {-2.5, 2}]}, None},
 TrackedSymbols :> {tick},
 Initialization :> (
   {
    field[x_Real, y_Real] := Module[{},
      (*heavy computation goes here*)
      {(2 (x - q1pos[[1]]))/
        EuclideanDistance[q1pos, {x, y}]^3 + (-2 (x - q2pos[[1]]))/

        EuclideanDistance[q2pos, {x, y}]^3, (2 (y - q1pos[[2]]))/
        EuclideanDistance[q1pos, {x, y}]^3 + (-2 (y - q2pos[[2]]))/
        EuclideanDistance[q2pos, {x, y}]^3}];
    fieldlines[q1pos_, q2pos_] := Module[{},
      (*heavy computation goes here*)
      StreamPlot[field[x, y], {x, -5, 5}, {y, -5, 5},
       StreamPoints -> pnts,
       StreamScale -> 1/20, ImageSize -> 600]];
    fieldpoint[q1pos_, q2pos_, pt_] := Module[{},
      (*heavy computation goes here*)

      StreamPlot[field[x, y], {x, -5, 5}, {y, -5, 5}, 
       StreamPoints -> {{{pt, {Thickness[0.005], RGBColor[1, 0, 0], 
            Arrowheads[0.02]}}}, Automatic, {ForwardBackward, 400}}, 
       ImageSize -> 600]];
    pnts = Tuples[{-3, -2, -1, 0, 1, 2, 3}, 2]
    }
   )
 ]

But there are problems with this code:




  1. The first run is very slow; the second run is ok (there must be some problem with the inizializaton).

  2. When I move the point P I can see that the Streamplot of the "background" field lines is not recalculated. That's fine and that's what I wanted. Anyway the single field line loses some of the specifications (arrows). The same thing happens when one of the charges q1 or q2 are moved.

  3. I'd like to use three Locator instead of three Slider2D for q1, q2 and P in my simulation, but I haven't found yet if that's possible and how to do that.


Any help?



Answer



You have few issues there. But nothing major. This runs much faster now. It also fixes the background field lines. Will add more comments later. For you third request, using Locators, needs more time. I'd actually suggest making a new question just for the locator question (your third question, i.e. changing Slider2D to Locator, since this is not related to this method itself and it is not a simple change as 1,2 questions you had).


This below addresses issue 1 and 2.


Some coding things fixed: need to make each function self contained. Do not reference Manipulate internal variables from the Initialization section functions. Pass all these via call parameters. Initialization section should not contain variables assignments. Only definitions (functions, and any other rules). Keep all variables inside Manipulate itself, or inside Modules inside Manipulate.



Added PerformanceGoal to Stream plots. few display changes.


One thing to note with this method, is that Manipulate variables needs to be explicitly initialized, this is the same as when using DynamicModule[{f=,b=},... where each symbol is initialized. This is needed, since Manipulate expression is evaluated first time, and it needs values for this variables. Other than this little house keeping, everything else is standard operating procedures.


enter image description here


Updated


This version has ContinuousAction -> option on each Dynamic. This way one can choose to make it false if needed. When it is true, it is much faster, but does not show the display as the mouse is being moved.


Manipulate[tick;
 Show[f2, f1, ImageSize -> 300],

 Text@Grid[{
    {Grid[{

       {"Q1"},
       {Slider2D[Dynamic[q1pos, {q1pos = #;
            f1 = fieldlines[q1pos, q2pos, pnts];
            f2 = fieldpoint[q1pos, q2pos, pt];
            tick = Not[tick]} &, SynchronousUpdating -> False], {{-6, -6}, {6, 6}}, 
             ContinuousAction -> True]},
       {Dynamic[q1pos]}
       }, Alignment -> Center]}
    ,
    {Grid[{{"Q2"},

       {Slider2D[Dynamic[q2pos, {q2pos = #;
            f1 = fieldlines[q1pos, q2pos, pnts];
            f2 = fieldpoint[q1pos, q2pos, pt];
            tick = Not[tick]} &, SynchronousUpdating -> False], {{-6, -6}, {6, 6}}, 
              ContinuousAction -> True]},
       {Dynamic[q2pos]}
       }, Alignment -> Center]}
    ,
    {Grid[{{"pt"},
       {Slider2D[Dynamic[pt, {pt = #;

            f2 = fieldpoint[q1pos, q2pos, pt];
            tick = Not[tick]} &, SynchronousUpdating -> False], {{-6, -6}, {6, 6}}, 
              ContinuousAction -> True]},
       {Dynamic[pt]}
       }, Alignment -> Center]}
    }, Spacings -> {.5, 1.5}, Alignment -> Center, Frame -> All
   ]
 ,
 {{tick, False}, None},
 {{q1pos, {-2, 0}}, None},

 {{q2pos, {2, 0}}, None},
 {{pt, {-2.5, 2}}, None},
 {{f1, fieldlines[{-2, 0}, {2, 0}, Tuples[{-3, -1, 0, 1, 3}, 2]]}, None},
 {{f2, fieldpoint[{-2, 0}, {2, 0}, {-2.5, 2}]}, None},
 (*{{pnts,Tuples[{-3,-2,-1,0,1,2,3},2]},None},*)
 {{pnts, Tuples[{-3, -1, 0, 1, 3}, 2]}, None},
 ControlPlacement -> Left,
 ContinuousAction -> False,
 SynchronousUpdating -> True,
 SynchronousInitialization -> False,

 TrackedSymbols :> {tick}, Initialization :> (

   field[x_, y_, q1pos_List, q2pos_List] := Module[{},
     {
      (2 (x - q1pos[[1]]))/EuclideanDistance[q1pos, {x, y}]^3 + 
        (-2 (x - q2pos[[1]]))/EuclideanDistance[q2pos, {x, y}]^3
      ,
      (2 (y - q1pos[[2]]))/EuclideanDistance[q1pos, {x, y}]^3 + 
         (-2 (y - q2pos[[2]]))/EuclideanDistance[q2pos, {x, y}]^3}
     ];


   fieldlines[q1pos_List, q2pos_List, pnts_List] := Module[{x, y},
     StreamPlot[field[x, y, q1pos, q2pos], {x, -5, 5}, {y, -5, 5},
      StreamPoints -> pnts, StreamScale -> Automatic , PerformanceGoal -> "Quality"]];

   fieldpoint[q1pos_List, q2pos_List, pt_List] := Module[{x, y},
     StreamPlot[field[x, y, q1pos, q2pos], {x, -5, 5}, {y, -5, 5},
      StreamPoints -> {
        {
         {pt, {Thickness[0.005], RGBColor[1, 0, 0], Arrowheads[0.02]}}

         }, Automatic, {ForwardBackward, 400}}, PerformanceGoal -> "Quality"]
     ]

   )
 ]

Original code


This version defaults to ContinuousAction -> true which makes it much slower, but does show the display as the mouse is being moved.


Manipulate[tick;
 Show[f2, f1, ImageSize -> 300],


 Text@Grid[{
    {Grid[{
       {"Q1"},
       {Slider2D[Dynamic[q1pos, {q1pos = #;
            f1 = fieldlines[q1pos, q2pos, pnts];
            f2 = fieldpoint[q1pos, q2pos, pt];
            tick = Not[tick]} &], {{-6, -6}, {6, 6}, {.1, .1}}]},
       {Dynamic[q1pos]}
       }, Alignment -> Center]}

    ,
    {Grid[{{"Q2"},
       {Slider2D[Dynamic[q2pos, {q2pos = #;
            f1 = fieldlines[q1pos, q2pos, pnts];
            f2 = fieldpoint[q1pos, q2pos, pt];
            tick = Not[tick]} &], {{-6, -6}, {6, 6}, {.1, .1}}]},
       {Dynamic[q2pos]}
       }, Alignment -> Center]}
    ,
    {Grid[{{"pt"},

       {Slider2D[Dynamic[pt, {pt = #;
            f2 = fieldpoint[q1pos, q2pos, pt];
            tick = Not[tick]} &], {{-6, -6}, {6, 6}, {.1, .1}}]},
       {Dynamic[pt]}
       }, Alignment -> Center]}
    }, Spacings -> {.5, 1.5}, Alignment -> Center, Frame -> All
   ]
 ,
 {{tick, False}, None},
 {{q1pos, {-2, 0}}, None},

 {{q2pos, {2, 0}}, None},
 {{pt, {-2.5, 2}}, None},
 {{f1, fieldlines[{-2, 0}, {2, 0}, Tuples[{-3, -2, -1, 0, 1, 2, 3}, 2]]}, None},
 {{f2, fieldpoint[{-2, 0}, {2, 0}, {-2.5, 2}]}, None},
 {{pnts, Tuples[{-3, -2, -1, 0, 1, 2, 3}, 2]}, None},
 ControlPlacement -> Left,
 ContinuousAction -> False,
 SynchronousInitialization -> False,
 TrackedSymbols :> {tick}, 
 Initialization :> (


   field[x_, y_, q1pos_List, q2pos_List] := Module[{},
     {
      (2 (x - q1pos[[1]]))/EuclideanDistance[q1pos, {x, y}]^3 + 
         (-2 (x - q2pos[[1]]))/EuclideanDistance[q2pos, {x, y}]^3
      ,
      (2 (y - q1pos[[2]]))/EuclideanDistance[q1pos, {x, y}]^3 + 
        (-2 (y - q2pos[[2]]))/EuclideanDistance[q2pos, {x, y}]^3}
     ];


   fieldlines[q1pos_List, q2pos_List, pnts_List] := Module[{x, y},
     StreamPlot[field[x, y, q1pos, q2pos], {x, -5, 5}, {y, -5, 5},
      StreamPoints -> pnts, StreamScale -> Automatic , PerformanceGoal -> "Quality"]];

   fieldpoint[q1pos_List, q2pos_List, pt_List] := Module[{x, y},
     StreamPlot[field[x, y, q1pos, q2pos], {x, -5, 5}, {y, -5, 5},
      StreamPoints -> {
        {
         {pt, {Thickness[0.005], RGBColor[1, 0, 0], Arrowheads[0.02]}}
         }, Automatic, {ForwardBackward, 400}}, PerformanceGoal -> "Quality"]

     ]

   )
 ]

Comments

Post a Comment

Popular posts from this blog

plotting - How to draw lines between specified dots on ListPlot?

I would like to create a plot where I have unconnected dots and some connected. So far, I have figured out how to draw the dots. My code is the following: ListPlot[{{1, 1}, {2, 2}, {3, 3}, {4, 4}, {1, 4}, {2, 5}, {3, 6}, {4, 7}, {1, 7}, {2, 8}, {3, 9}, {4, 10}, {1, 10}, {2, 11}, {3, 12}, {4,13}, {2.5, 7}}, Ticks -> {{1, 2, 3, 4}, None}, AxesStyle -> Thin, TicksStyle -> Directive[Black, Bold, 12], Mesh -> Full] I have thought using ListLinePlot command, but I don't know how to specify to the command to draw only selected lines between the dots. Do have any suggestions/hints on how to do that? Thank you. Answer One possibility would be to use Epilog with Line : ListPlot[ {{1, 1}, {2, 2}, {3, 3}, {4, 4}, {1, 4}, {2, 5}, {3, 6}, {4, 7}, {1, 7}, {2, 8}, {3, 9}, {4, 10}, {1, 10}, {2, 11}, {3, 12}, {4, 13}, {2.5, 7}}, Ticks -> {{1, 2, 3, 4}, None}, AxesStyle -> Thin, TicksStyle -> Directive[Black, Bold, 12], Mesh -> Full, Epilog -> { Line[ ...
Post a Comment
Read more

equation solving - Invert and fit implicitly defined curve

I need to fit an implicitly defined curve. I thought I could get some data out of Solve , and then using FindFit . Therefore, I would like to find the relation the parametric curve defined by $F(x,y)=0$: Solve[-(1/2) + 1/2 (0.41202 BesselK[0, 0.1 Sqrt[x^2 + y^2]] + (0.101483 x BesselK[1, 0.1 Sqrt[x^2 + y^2]])/Sqrt[x^2 + y^2]) == 0, y] But I can't get an output: Solve was unable to solve the system with inexact coefficients or the system obtained by direct rationalization of inexact numbers present in the system. Since many of the methods used by Solve require exact input, providing Solve with an exact version of the system may help. >> Edit: In particular, I would like to fit the data coming from the curve with the expression of another curve, and not with a function $f(x)$. In particular, since this clearly looks like a cardioid , I would like it to fit to something like it. What other strategies could I try?
Post a Comment
Read more

dynamic - How can I make a clickable ArrayPlot that returns input?

I would like to create a dynamic ArrayPlot so that the rectangles, when clicked, provide the input. Can I use ArrayPlot for this? Or is there something else I should have to use? Answer ArrayPlot is much more than just a simple array like Grid : it represents a ranged 2D dataset, and its visualization can be finetuned by options like DataReversed and DataRange . These features make it quite complicated to reproduce the same layout and order with Grid . Here I offer AnnotatedArrayPlot which comes in handy when your dataset is more than just a flat 2D array. The dynamic interface allows highlighting individual cells and possibly interacting with them. AnnotatedArrayPlot works the same way as ArrayPlot and accepts the same options plus Enabled , HighlightCoordinates , HighlightStyle and HighlightElementFunction . data = {{Missing["HasSomeMoreData"], GrayLevel[ 1], {RGBColor[0, 1, 1], RGBColor[0, 0, 1], GrayLevel[1]}, RGBColor[0, 1, 0]}, {GrayLevel[0], GrayLevel...
Post a Comment
Read more