differential equations - Integrating a solution of NDSolve into table

So I am working with a set of three coupled DEs that I numerically solve. This is simple enough

NDSolve[{N1'[t] == -R1[ef]*N1[t] + b1*Γ0*N2[t], 
         N2'[t] == +R1[ef]*N1[t] - Γ0*N2[t] , 
         N3'[t] == b2*Γ0*N2[t] - Γ0/2 N3[t], 
         N1[0] == .65, N2[0] == 0, N3[0] == 0}, 

         {N1, N2, N3}, {t, 0, 300}]

Then I integrate my N3 function (times t)

NIntegrate[t*Evaluate[N2[t] /. s], {t, 0, 300}]

In my DE's I have R=-Log[1-ef] , so what I want to know is how can I make a table (or anything) that will go through, solve this and calculate that integral as a function of ef?

Thanks

Answer

Method I

With some valuable input from @halirutan, we will be able to integrate outside ParametricNDSolve and plot the resulting function,

b1 = 1; Γ0 = 2; b2 = 1;
R1 = -Log[1 - ef]
sol = ParametricNDSolve[{N1'[t] == -R1*N1[t] + b1*Γ0*N2[t], 
   N2'[t] == +R1*N1[t] - Γ0*N2[t], 
   N3'[t] == b2*Γ0*N2[t] - Γ0/2 N3[t], 
   N1[0] == .65, N2[0] == 0, N3[0] == 0},
   {N1, N2, N3}, {t, 0, 300}, {ef}]
Table[NIntegrate[t*N2[ef][t] /. sol, {t, 0, 300}], {ef, 0.1, 0.5, 0.1}]

{1463.78, 2935.9, 4426.87, 5950.87, 7528.18}

ListLinePlot[%, DataRange -> {0.1, 0.5}, Frame -> True]

Method II

Considering, @CarlWoll suggestion, we can get the same result as we have from method I.

sol1 = ParametricNDSolve[{N1'[t] == -R1*N1[t] + 
     b1*Γ0*N2[t], 
   N2'[t] == +R1*N1[t] - Γ0*N2[t], 

   N3'[t] == b2*Γ0*N2[t] - Γ0/2 N3[t], 
   N1[0] == .65, N2[0] == 0, N3[0] == 0, N4'[t] == t N2[t], 
   N4[0] == 0}, {N1, N2, N3, N4}, {t, 0, 300}, {ef}];

f[ef_] = (N4[ef][t] /. sol1 /. t -> 300 - N4[ef][t] /. sol1 /. t -> 0);

Table[Evaluate[f[ef]], {ef, 0.1, 0.5, 0.1}]

{1463.78, 2935.9, 4426.87, 5950.87, 7528.18}

Method III

sol2[ef_] := 
 NDSolve[{N1'[t] == -(-Log[1 - ef])*N1[t] + b1*Γ0*N2[t],
    N2'[t] == (-Log[1 - ef])*N1[t] - Γ0*N2[t], 
   N3'[t] == b2*Γ0*N2[t] - Γ0/2 N3[t], 
   N1[0] == .65, N2[0] == 0, N3[0] == 0, N4'[t] == t N2[t], 
   N4[0] == 0}, {N1, N2, N3, N4}, {t, 0, 300}];

f[ef_] = N4[t] /. (sol2 /@ {0.1, 0.2, 0.3, 0.4, 0.5}) /. t -> 300

{{1463.78}, {2935.9}, {4426.87}, {5950.87}, {7528.18}}