What will happen, if I don't specify random seed by SeedRandom function?

Suppose I want to run several times of the same code containing RandomReal function, but I don't initialise the random seed. What will happen?

I tried, but each time the RandomReal[] return different values, does it mean that Mathematica using some kind of default method to initialise the random number generator even without SeedRandom[]?

Answer

Let's think about when the answer to this question may be relevant. You know that if using the same seed on two different occasions, the RNG will generate the same sequence of numbers. So the relevant questions are:

1. 
   

   Does Mathematica use the same seed after startup every time?

   
   

   No. This is easy to test.

   
   



2. 
   

   Many programs take the seed from the system time. Also, the SeedRandom documentation says that "SeedRandom[] resets the generator, using as a seed the time of day and certain attributes of the current Wolfram System session." Is this what Mathematica does on startup?

   
   

   Yes. On OS X I ran the following in a terminal:

   
   

   math -run Print@RandomReal[] & math -run Print@RandomReal[]
   

   
   

   That is, I started two kernels at the same time and checked if they generate the same sequence of random numbers. They do.

   
   


3. 
   

   If the seed is taken from the system time, what about parallelization? What if I start up all parallel kernels at the same time? Will they all use the same seed?

   
   

   No. The Parallel Tools package takes care of this. Each kernel will use a different seed. You can easily test this using ParallelTable[RandomReal[], {$ProcessorCount}]. You'll get a list of different numbers.

   
   
   


4. 
   

   Okay, but what if instead of using in-Mathematica parallelization, I manually run several Mathematica processes in parallel, say on a HPC cluster?

   
   

   Modern operating systems come with a nondeterministic random number generator. This gives truly unpredictable random numbers using entropy sources such as keystrokes and network traffic, and is used for cryptographical purposes. You can take the seed from there. Here's a function I used for this in the past. It's only for Unix-like systems (OS X and Linux):

   
   

   (* Nondeterministic random numbers from the OS *)
   
   NondeterministicRandomInteger::usage = "NondeterministicRandomInteger[] returns an unpredictable random integer between 0..2^32-1.";
   
   NondeterministicRandomInteger::notsupp = "Not supported on ``";
   
   
   Switch[$OperatingSystem,
             "MacOSX"|"Unix",
             NondeterministicRandomInteger[] :=
                 AbortProtect@Module[{stream, res},
                   stream = OpenRead["!head -c 4 /dev/random", BinaryFormat -> True];
                   res = BinaryRead[stream, "UnsignedInteger32"];
                   Close[stream];
                   res
                 ],
             _,
   
             NondeterministicRandomInteger[] := (Message[NondeterministicRandomInteger::notsupp, $OperatingSystem]; $Failed)
   ]
   

   
   

   Use this only for seeding: SeedRandom@NondeterministicRandomInteger[].

   
   

   If I did this today, I would use something like boost::random_device through LibraryLink for a better cross platform solution that also works on Windows.